PROJETO - SENSOR DE TEMPERATURA E UMIDADE

Este projeto visa medir a temperatura e umidade do ambiente utilizando o sensor RHT03






Componentes necessrios:

- Protoboard
- Sensor RHT03
- Resistor de 1kohm
- Fios Jumper





Projeto - Sensor de Temperatura e umidade

O RHT03 um sensor de temperatura e umidade com interface digital de fcil
utilizao. Este sensor j calibrado e no necessita de componentes extras para o
funcionamento.
Para utilizar o RHT03 com o Arduino necessrio o uso das bibliotecas dht.cpp e dth.h
que podem ser encontradas no site oficial do arduino (link) ou no anexo deste documento.
O sensor possui 4 pinos, sendo apenas um deles responsvel por realizar a leitura dos
dados (este pino exige um resistor de Pull-UP). A pinagem deste sensor pode ser observada na
figura A.

Figura A - Pinagem do Sensor RHT03


Conectando os componentes
Conecte seu circuito como mostra a figura abaixo.


Figura B - Circuito


O sensor RHT03 funciona na faixa de 3.3v a 6v, neste projeto foi utilizada a sada de 5v
do arduino. O pino 2 do sensor foi conectado na porta digital 10 do arduino com um resistor de
1kohm de Pull-up (marrom-preto-vermelho). O pino 3 fica sem conexo, e por fim, o pino 4 que
fica conectado no GND do arduino.


Programao
O primeiro passo a ser realizado criar uma pasta denominada DHT e colocar dentro
dela os arquivos dht.cpp e dth.h. Aps isso, coloque esta pasta no diretrio libraries da IDE do
Arduino.
Agora, abra seu IDE do Arduino e digite o cdigo a seguir.

//importacao da biblioteca DHT
#include <dht.h>

//cria um objeto do tipo dht
dht DHT;

//constante que define a leitura do sensor no pino digital 10
#define DHT22_PIN 10

//cria variavies p/ armazenar os valores da leitura
double vtemperatura, vhumidade;

void setup(){
Serial.begin(9600);
Serial.println("Humidade (%),\tTemperatura (C)");
}

void loop(){
//realiza a leitura do sensor
DHT.read22(DHT22_PIN);

//armazena os valores nas variaveis
vhumidade = DHT.humidity;
vtemperatura = DHT.temperature;

//realiza a impressao ao usuario
Serial.print(vhumidade);
Serial.print(",\t");
Serial.println(vtemperatura);

//espera 1 segundo para realizar novamente a leitura
delay(1000);
}







Resultado
Aps realizar o upload do cdigo para o arduno, clique em Serial Monitor (IDE do
Arduino), e ver os valores de umidade e temperatura do seu ambiente, como pode ser visto na
figura C.


Figura C - Resultado Sensor RHT03






















Anexo

A - dht.h

// FILE: dht.h
// VERSION: 0.1.03
// PURPOSE: DHT Temperature & Humidity Sensor library for Arduino
//
// URL: http://arduino.cc/playground/Main/DHTLib
//
// HISTORY:
// see dht.cpp file
//

#ifndef dht_h
#define dht_h

#if ARDUINO < 100
#include <WProgram.h>
#else
#include <Arduino.h>
#endif

#define DHT_LIB_VERSION "0.1.03"

#define DHTLIB_OK 0
#define DHTLIB_ERROR_CHECKSUM -1
#define DHTLIB_ERROR_TIMEOUT -2

class dht
{
public:
int read11(uint8_t pin);
int read22(uint8_t pin);
double humidity;
double temperature;

private:
uint8_t bits[5]; // buffer to receive data
int read(uint8_t pin);
};
#endif
//
// END OF FILE
//










B - dht.cpp


//
// FILE: dht.cpp
// VERSION: 0.1.03
// PURPOSE: DHT Temperature & Humidity Sensor library for Arduino
//
// DATASHEET:
//
// HISTORY:
// 0.1.03 added error values for temp and humidity when read failed
// 0.1.02 added error codes
// 0.1.01 added support for Arduino 1.0, fixed typos (31/12/2011)
// 0.1.0 by Rob Tillaart (01/04/2011)
// inspired by DHT11 library
//

#include "dht.h"
#define TIMEOUT 10000

/////////////////////////////////////////////////////
//
// PUBLIC
//

// return values:
// DHTLIB_OK
// DHTLIB_ERROR_CHECKSUM
// DHTLIB_ERROR_TIMEOUT
int dht::read11(uint8_t pin)
{
// READ VALUES
int rv = read(pin);
if (rv != 0)
{
humidity = -999; // invalid value, or is NaN prefered?
temperature = -999; // invalid value
return rv;
}

// CONVERT AND STORE
humidity = bits[0]; // bit[1] == 0;
temperature = bits[2]; // bits[3] == 0;

// TEST CHECKSUM
uint8_t sum = bits[0] + bits[2]; // bits[1] && bits[3] both 0
if (bits[4] != sum) return DHTLIB_ERROR_CHECKSUM;

return DHTLIB_OK;
}

// return values:
// DHTLIB_OK
// DHTLIB_ERROR_CHECKSUM
// DHTLIB_ERROR_TIMEOUT
int dht::read22(uint8_t pin)

{
// READ VALUES
int rv = read(pin);
if (rv != 0)
{
humidity = -999; // invalid value, or is NaN prefered?
temperature = -999; // invalid value
return rv;
}

// CONVERT AND STORE
humidity = word(bits[0], bits[1]) * 0.1;

int sign = 1;
if (bits[2] & 0x80) // negative temperature
{
bits[2] = bits[2] & 0x7F;
sign = -1;
}
temperature = sign * word(bits[2], bits[3]) * 0.1;

// TEST CHECKSUM
uint8_t sum = bits[0] + bits[1] + bits[2] + bits[3];
if (bits[4] != sum) return DHTLIB_ERROR_CHECKSUM;

return DHTLIB_OK;
}

/////////////////////////////////////////////////////
//
// PRIVATE
//

// return values:
// DHTLIB_OK
// DHTLIB_ERROR_TIMEOUT
int dht::read(uint8_t pin)
{
// INIT BUFFERVAR TO RECEIVE DATA
uint8_t cnt = 7;
uint8_t idx = 0;

// EMPTY BUFFER
for (int i=0; i< 5; i++) bits[i] = 0;

// REQUEST SAMPLE
pinMode(pin, OUTPUT);
digitalWrite(pin, LOW);
delay(20);
digitalWrite(pin, HIGH);
delayMicroseconds(40);
pinMode(pin, INPUT);

// GET ACKNOWLEDGE or TIMEOUT
unsigned int loopCnt = TIMEOUT;
while(digitalRead(pin) == LOW)
if (loopCnt-- == 0) return DHTLIB_ERROR_TIMEOUT;


loopCnt = TIMEOUT;
while(digitalRead(pin) == HIGH)
if (loopCnt-- == 0) return DHTLIB_ERROR_TIMEOUT;

// READ THE OUTPUT - 40 BITS => 5 BYTES
for (int i=0; i<40; i++)
{
loopCnt = TIMEOUT;
while(digitalRead(pin) == LOW)
if (loopCnt-- == 0) return DHTLIB_ERROR_TIMEOUT;

unsigned long t = micros();

loopCnt = TIMEOUT;
while(digitalRead(pin) == HIGH)
if (loopCnt-- == 0) return DHTLIB_ERROR_TIMEOUT;

if ((micros() - t) > 40) bits[idx] |= (1 << cnt);
if (cnt == 0) // next byte?
{
cnt = 7;
idx++;
}
else cnt--;
}

return DHTLIB_OK;
}
//
// END OF FILE
//