Вы находитесь на странице: 1из 18

ВПР

Ищет значение в первом столбце массива таблицы и возвращает значение в той же строке из другого
столбца массива таблицы.

Буква В в названии функции ВПР означает «вертикально». Функция ВПР используется вместо функции ГПР,
если сравниваемые значения расположены в столбце слева от искомых данных.

Синтаксис

ВПР(искомое_значение;таблица;номер_столбца;интервальный_просмотр)

Искомое_значение — значение, которое должно быть найдено в первом столбце табличногомассива. Этот
аргумент может быть значением или ссылкой. Если искомое_значение меньше, чем наименьшее значение в
первом столбце табличного массива, функция ВПР возвращает значение ошибки #Н/Д.

Таблица — два или более столбцов данных. Можно использовать ссылку на диапазон или имя диапазона.
Значения в первом столбце аргумента «таблица» — это значения, в которых выполняется поиск аргумента
«искомое_значение». Эти значения могут быть текстовыми, числовыми или логическими. Текстовые значения
в нижнем и верхнем регистре считаются эквивалентными.

Номер_столбца — номер столбца в аргументе «таблица», из которого возвращается соответствующее


значение. Если номер_столбца = 1, то возвращается значение из первого столбца таблицы; если
номер_столбца = 2 — значение из второго столбца таблицы и т. д. Если значение аргумента
«номер_столбца»:

• меньше 1, функция ВПР возвращает значение ошибки #ЗНАЧ!;

• больше, чем число столбцов в таблице, функция ВПР возвращает значение ошибки #ССЫЛ!.

Интервальный_просмотр — логическое значение, определяющее, какое соответствие должна найти


функция ВПР — точное или приблизительное.

• Если этот аргумент имеет значение ИСТИНА или опущен, то возвращается точное или

приблизительное значение. Если точное соответствие не найдено, то возвращается наибольшее значение,

которое меньше, чем искомое_значение.

Значения в первом столбце аргумента «таблица» должны быть расположены в возрастающем


порядке, иначе функция ВПР может возвратить неправильный результат. Дополнительные
сведения см. в разделе Сортировка данных.

• Если данный аргумент имеет значение ЛОЖЬ, функция ВПР ищет только точное соответствие. В

этом случае сортировка значений в первом столбце аргумента «таблица» не обязательна. Если в этом

первом столбце имеется два или более значений, соответствующих аргументу «искомое_значение»,
используется первое найденное значение. Если точное соответствие не найдено, возвращается значение

ошибки #Н/Д.

ЗАМЕЧАНИЯ

• При поиске текстовых значений в первом столбце аргумента «таблица» убедитесь, что данные в

этом столбце не содержат начальных пробелов, конечных пробелов, используемых не по правилам

прямых ( ' или " ) и фигурных ( ‘ или “ ) кавычек или непечатаемых знаков. В этих случаях функция ВПР

может возвратить неправильное или непредвиденное значение. Дополнительные сведения см. в описании

функции ПЕЧСИМВ и СЖПРОБЕЛЫ.

• При поиске числовых значений или значений дат убедитесь, что формат данных в первом столбце

таблицы не является текстовым. В этом случае функция ВПР может возвратить неправильное или

непредвиденное значение. Дополнительные сведения см. в разделе Преобразование чисел из текстового

формата в числовой.

• Если значение аргумента «интервальный_просмотр» — ЛОЖЬ, а аргумент «искомое_значение»

представляет собой текст, то в аргументе «искомое_значение» допускается использование

подстановочных знаков: вопросительного знака (?) и звездочки (*). Вопросительный знак соответствует

любому знаку; звездочка — любой последовательности знаков. Чтобы найти сами эти знаки, следует

поставить перед ними знак тильды (~).

ПРИМЕР 1

Чтобы этот пример проще было понять, скопируйте его на пустой лист.

Копирование примера

1. Создайте пустую книгу или лист.

2. Выделите пример в разделе справки.

3. Нажмите клавиши CTRL+C.

4. На листе выделите ячейку A1 и нажмите клавиши CTRL+V.

5. Чтобы переключиться из режима просмотра результатов в режим просмотра формул, возвращающих


эти результаты, нажмите клавиши CTRL+` (апостроф) или на вкладке Формулы в группе Зависимости
формул нажмите кнопку Показать формулы.

В данном примере выполняется поиск значений в столбце «Плотность» для нахождения соответствующих
значений в столбцах «Вязкость» и «Температура» в таблице атмосферных свойств. (Значения даны для
воздуха при температуре 0°C и давлении в 1 атмосферу.)
А B C
1 Плотность Вязкость Температура
2 0,457 3,55 500
3 0,525 3,25 400
4 0,616 2,93 300
5 0,675 2,75 250
6 0,746 2,57 200
7 0,835 2,38 150
8 0,946 2,17 100
9 1,09 1,95 50
10 1,29 1,71 0

Формула Описание (результат)


=ВПР(1;A2:C10;2) Используя приблизительное соответствие, функция ищет в
столбце A значение 1, находит наибольшее значение, которое
меньше или равно 1 и составляет 0,946, а затем возвращает
значение из столбца B в той же строке (2,17)
=ВПР(1;A2:C10;3;ИСТИНА) Используя приблизительное соответствие, функция ищет в
столбце A значение 1, находит наибольшее значение, которое
меньше или равно 1 и составляет 0,946, а затем возвращает
значение из столбца C в той же строке (100)
=ВПР(0,7;A2:C10;3;ЛОЖЬ) Используя точное соответствие, функция ищет в столбце A
значение 0,7. Поскольку точного соответствия нет, возвращается
сообщение об ошибке (#Н/Д)
=ВПР(0,1;A2:C10;2;ИСТИНА) Используя приблизительное соответствие, функция ищет в
столбце A значение 0,1. Поскольку 0,1 меньше наименьшего
значения в столбце A, возвращается сообщение об ошибке (#Н/Д)
=ВПР(2;A2:C10;2;ИСТИНА) Используя приблизительное соответствие, функция ищет в
столбце A значение 2, находит наибольшее значение, которое
меньше или равно 2 и составляет 1,29, а затем возвращает
значение из столбца B в той же строке (1,71)

ПРИМЕР 2

Чтобы этот пример проще было понять, скопируйте его на пустой лист.

Копирование примера

1. Создайте пустую книгу или лист.

2. Выделите пример в разделе справки.

3. Нажмите клавиши CTRL+C.

4. На листе выделите ячейку A1 и нажмите клавиши CTRL+V.

5. Чтобы переключиться из режима просмотра результатов в режим просмотра формул, возвращающих


эти результаты, нажмите клавиши CTRL+` (апостроф) или на вкладке Формулы в группе Зависимости
формул нажмите кнопку Показать формулы.

В данном примере выполняется поиск значений в столбце «Код изделия» в таблице с детскими товарами для
нахождения соответствующих значений в столбцах «Стоимость» и «Наценка», проверки условий и
вычисления цены.
A B C D
1 Код изделия Изделие Стоимость Наценка
2 ST-340 Коляска 1 456,70р. 30%
3 BI-567 Нагрудник 35,60р. 40%
4 DI-328 Пеленки 214,50р. 35%
5 WI-989 Салфетки 51,20р. 40%
6 AS-469 Аспиратор 25,60р. 45%

Формула Описание (результат)


= ВПР("DI-328"; A2:D6; 3; ЛОЖЬ) * (1 + Вычисление розничной цены пеленок путем
ВПР("DI-328"; A2:D6; 4; ЛОЖЬ)) добавления процента наценки к стоимости
(289,6р.)
= (ВПР("WI-989"; A2:D6; 3; ЛОЖЬ) * (1 + Вычисление отпускной цены салфеток путем
ВПР("WI-989"; A2:D6; 4; ЛОЖЬ))) * (1 - вычитания указанной скидки из розничной
20%) цены (57,3р.)
=ЕСЛИ(ВПР(A2; A2:D6; 3; ЛОЖЬ) >= Если стоимость изделия больше или равна
200; "Наценка составляет " & 100 * 200р., отображается строка «Наценка
ВПР(A2; A2:D6; 4; ЛОЖЬ) &"%"; составляет nn%»; в противном случае
"Стоимость меньше 200р.") отображается строка «Стоимость меньше
200р.» (наценка составляет 30%)
= ЕСЛИ(ВПР(A3; A2:D6; 3; ЛОЖЬ) >= Если стоимость изделия больше или равна
200; "Наценка составляет: " & 100 * 200р., отображается строка «Наценка
ВПР(A3; A2:D6; 4; ЛОЖЬ) &"%"; составляет nn%»; в противном случае
"Стоимость составляет " & ВПР(A3; отображается строка «Стоимость составляет
A2:D6; 3; ЛОЖЬ)) n,nn» (стоимость составляет 35,6)

ПРИМЕР 3

Чтобы этот пример проще было понять, скопируйте его на пустой лист.

Копирование примера

1. Создайте пустую книгу или лист.

2. Выделите пример в разделе справки.

3. Нажмите клавиши CTRL+C.

4. На листе выделите ячейку A1 и нажмите клавиши CTRL+V.

5. Чтобы переключиться из режима просмотра результатов в режим просмотра формул, возвращающих


эти результаты, нажмите клавиши CTRL+` (апостроф) или на вкладке Формулы в группе Зависимости
формул нажмите кнопку Показать формулы.

В данном примере выполняется поиск значений в столбце «Номер» в таблице сотрудников для вычисления
возраста сотрудников с помощью значений в других столбцах, а также проверка неверных условий.
A B C D E
1 Номер Имя Должность Дата
Фамилия рождения

2 1 Орехов Алексей Торговый 08.12.68


представитель

3 2 Ушаков Валерий Вице-президент 19.02.52


по продажам

4 3 Ожогина Инна Торговый 30.08.63


представитель

5 4 Попкова Дарья Торговый 19.09.58


представитель

6 5 Песоцкий Станислав Менеджер по 04.03.55


продажам

7 6 Сергиенко Мария Торговый 02.07.63


представитель

Формула Описание (результат)


=ЦЕЛОЕ(ДОЛЯГОДА(ДАТА(2004;6;30); Вычисление для 2004
ВПР(5;A2:E7;5; ЛОЖЬ); 1)) финансового года
возраста сотрудника под
номером 5. Функция
ДОЛЯГОДА используется
для вычитания даты
рождения из конечной
даты финансового года и
отображения результата в
виде целого числа с
помощью функции ЦЕЛОЕ
(49)
=ЕСЛИ(ЕНД(ВПР(5;A2:E7;2;ЛОЖЬ)) = При наличии сотрудника
ИСТИНА; "Сотрудник не найден"; под номером 5
ВПР(5;A2:E7;2;ЛОЖЬ)) отображается его
фамилия; в противном
случае отображается
сообщение «Сотрудник не
найден» (Песоцкий).
Функция ЕНД возвращает
значение ИСТИНА, если
функция ВПР возвращает
значение ошибки #НД
=ЕСЛИ(ЕНД(ВПР(15;A3:E8;2;ЛОЖЬ)) = При наличии сотрудника
ИСТИНА; "Сотрудник не найден"; под номером 15
ВПР(15;A3:E8;2;ЛОЖЬ)) отображается его
фамилия; в противном
случае отображается
сообщение «Сотрудник не
найден» (Сотрудник не
найден).
Функция ЕНД возвращает
значение ИСТИНА, если
функция ВПР возвращает
значение ошибки #НД
=ВПР(4;A2:E7;3;ЛОЖЬ) & " " & Для сотрудника под
ВПР(4;A2:E7;2;ЛОЖЬ) & " — это " & номером 4 значения трех
ВПР(4;A2:E7;4;ЛОЖЬ) & "." ячеек объединяются в
целое предложение
(Дарья Попкова — это
торговый представитель.)

Поиск значений в списке данных


Показать все
Предположим, что требуется найти внутренний телефонный номер сотрудника по его идентификационному
номеру или узнать ставку комиссионного вознаграждения, предусмотренную за определенный объем продаж.
Необходимые данные можно быстро и эффективно находить в списке и автоматически проверять их
правильность. Значения, возвращенные поиском, можно затем использовать в вычислениях или отображать
как результаты. Существует несколько способов поиска значений в списке данных и отображения
результатов.

Предполагаемое действие:

• Поиск значений в списке по вертикали по точному совпадению


• Поиск значений в списке по вертикали по приблизительному совпадению
• Поиск значений в списке по горизонтали по точному совпадению
• Поиск значений в списке по горизонтали по приблизительному совпадению
• Создание формулы подстановки с помощью мастера подстановок
• Поиск значений в списке по вертикали по точному совпадению
• Поиск значений по вертикали в списке неизвестного размера по точному совпадению

Поиск значений в списке по вертикали по точному


совпадению

Для выполнения этой задачи используется функция ВПР.

ПРИМЕР

Чтобы этот пример проще было понять, скопируйте его на пустой лист.

Копирование примера

1. Выделите пример в этом разделе. При копировании примера в приложение Excel Web App
выполняйте копирование и вставку по одной ячейке за раз.

2. Нажмите сочетание клавиш CTRL+C.

3. Создайте пустую книгу или лист.

4. Выделите на листе ячейку A1 и нажмите сочетание клавиш CTRL+V. При работе в Excel Web App
повторите копирование и вставку для всех ячеек в примере.

5. Чтобы переключиться между просмотром результатов и просмотром формул, возвращающих эти


результаты, нажмите клавиши CTRL+` (апостроф) или на вкладке Формулы в группе Зависимости
формул нажмите кнопку Показать формулы.
A B C D
1 Идентификационный Фамилия Имя Добавочный
номер номер
2
ИН-34567 Белов Валентин 5467
3
ИН-16782 Фокин Андрей 3457
4
ИН-4537 Ожогина Инна 3355
5
ИН-1873 Попкова Дарья 5176
6
ИН-3456 Песоцкий Станислав 3453
7
ИН-5678 Сергиенко Мария 3428
8
Формула Описание (результат)

=ВПР("ИН-4537"; A1:D7; Поиск идентификационного номера ИН-4537 в первом


9 4; ЛОЖЬ) столбце и возвращение значения из той же строки
четвертого столбца (3355)

Дополнительные сведения об использовании этой функции см. в статье Функция ВПР.

К НАЧАЛУ СТРАНИЦЫ

Поиск значений в списке по вертикали по


приблизительному совпадению

Для выполнения этой задачи используется функция ВПР.

ВАЖНО. Данный метод работает только при условии, что значения в первом столбце были отсортированы
по возрастанию.

ПРИМЕР

Чтобы этот пример проще было понять, скопируйте его на пустой лист.

Копирование примера

6. Выделите пример в этом разделе. При копировании примера в приложение Excel Web App
выполняйте копирование и вставку по одной ячейке за раз.

7. Нажмите сочетание клавиш CTRL+C.

8. Создайте пустую книгу или лист.

9. Выделите на листе ячейку A1 и нажмите сочетание клавиш CTRL+V. При работе в Excel Web App
повторите копирование и вставку для всех ячеек в примере.

10. Чтобы переключиться между просмотром результатов и просмотром формул, возвращающих эти
результаты, нажмите клавиши CTRL+` (апостроф) или на вкладке Формулы в группе Зависимости
формул нажмите кнопку Показать формулы.

В данном примере известна частота и требуется найти соответствующий ей цвет.


A B
1 Частота Цвет
2 4,14 красный
3 4,19 оранжевый
4 5,17 желтый
5 5,77 зеленый
6 6,39 синий
7 Формула Описание (результат)

=ВПР(5,93; A1:B6; Поиск значения 5,93 в столбце A, нахождение наибольшего значения, меньшего 5,93 (5,77), и
2; ИСТИНА) возвращение соответствующего ему значения из столбца B, находящегося в той же строке,
что и 5,77 (зеленый)
8

Дополнительные сведения об использовании этой функции см. в статье Функция ВПР.

К НАЧАЛУ СТРАНИЦЫ

Поиск значений в списке по горизонтали по точному


совпадению

Для выполнения этой задачи используется функция ГПР.

ПРИМЕР

Чтобы этот пример проще было понять, скопируйте его на пустой лист.

Копирование примера

11. Выделите пример в этом разделе. При копировании примера в приложение Excel Web App
выполняйте копирование и вставку по одной ячейке за раз.

12. Нажмите сочетание клавиш CTRL+C.

13. Создайте пустую книгу или лист.

14. Выделите на листе ячейку A1 и нажмите сочетание клавиш CTRL+V. При работе в Excel Web App
повторите копирование и вставку для всех ячеек в примере.

15. Чтобы переключиться между просмотром результатов и просмотром формул, возвращающих эти
результаты, нажмите клавиши CTRL+` (апостроф) или на вкладке Формулы в группе Зависимости
формул нажмите кнопку Показать формулы.
A B БОЛТЫ
1 Состояние Оси 9
2 На складе 4 10
3 Заказано 5 11
4 Задолженность 6
5 Формула Описание (результат)
6 =ГПР("Болты", A1:C4, 3, Поиск значения «Болты» в строке 1 и возвращение значения из строки 3,
ЛОЖЬ) находящейся в том же столбце (10)

Дополнительные сведения об использовании этой функции см. в статье Функция ГПР.

К НАЧАЛУ СТРАНИЦЫ

Поиск значений в списке по горизонтали по


приблизительному совпадению

Для выполнения этой задачи используется функция ГПР.

ВАЖНО. Данный метод работает только при условии, что значения в первой строке были отсортированы по
возрастанию.

ПРИМЕР

Чтобы этот пример проще было понять, скопируйте его на пустой лист.

Копирование примера

1. Создайте пустую книгу или лист.

2. Выделите пример в разделе справки.

16. Выделите пример в этом разделе. При копировании примера в приложение Excel Web App
выполняйте копирование и вставку по одной ячейке за раз.

17. Нажмите сочетание клавиш CTRL+C.

18. Создайте пустую книгу или лист.

19. Выделите на листе ячейку A1 и нажмите сочетание клавиш CTRL+V. При работе в Excel Web App
повторите копирование и вставку для всех ячеек в примере.

20. Чтобы переключиться между просмотром результатов и просмотром формул, возвращающих эти
результаты, нажмите клавиши CTRL+` (апостроф) или на вкладке Формулы в группе Зависимости
формул нажмите кнопку Показать формулы.

3. Нажмите клавиши CTRL+C.

4. На листе выделите ячейку A1 и нажмите клавиши CTRL+V.


5. Чтобы перейти от просмотра результатов к просмотру формул, возвращающих эти результаты,
нажмите клавиши CTRL+` (знак ударения) или на вкладке Формулы в группе Зависимости формул
нажмите кнопку Показать формулы.

A B C D
1 10000 50000 100000 Объем
2 продаж
3
0,05 0,20 0,30 Ставка
Формула Описание (результат)
=ГПР(78658;A1:D4;2; Поиск значения 78 658р. в строке 1, нахождение наибольшего
ИСТИНА) значения, меньшего 78 658р. (50 000р.), и возвращение значения
из строки 2, находящегося в том же столбце, что и 50 000р. (20%)

ПРИМЕЧАНИЯ

• Ставку и возвращаемое число можно отобразить как процент. Выделите ячейку и на вкладке

Главная в группе Число нажмите кнопку Процентный формат .

• Числа в столбце объема продаж можно отобразить в рублях. Выделите ячейку и на вкладке Главная

в группе Число нажмите кнопку Финансовый числовой формат .

Дополнительные сведения об использовании этой функции см. в статье Функция ГПР.

К НАЧАЛУ СТРАНИЦЫ

Создание формулы подстановки с помощью мастера


подстановок

Мастер подстановок создает формулу подстановки, основанную на данных листа, содержащих заголовки
строк и столбцов. С помощью мастера подстановок можно найти остальные значения в строке, если известно
значение в одном столбце, и наоборот. В формулах, которые создает мастер подстановок, используются
функции ИНДЕКС и ПОИСКПОЗ.

1. Щелкните ячейку в диапазоне.

2. На вкладке Формулы в группе Решения выберите команду Подстановка.

Если команда Подстановка недоступна, необходимо загрузить надстройку мастера подстановок.

Загрузка надстройки мастера подстановок

1. Нажмите кнопку Microsoft Office , щелкните Параметры Excel, а затем выберите


категорию Надстройки.

2. В поле Управление выберите значениеНадстройки Excel и нажмите кнопку Перейти.


3. В диалоговом окне Список надстроек установите флажок рядом с пунктом Мастер
подстановок и нажмите кнопку ОК.

3. Следуйте указаниям мастера.

К НАЧАЛУ СТРАНИЦЫ

Поиск значений в списке по вертикали по точному


совпадению

Для выполнения этой задачи используются функции ИНДЕКС и ПОИСКПОЗ.

ПРИМЕР

Чтобы этот пример проще было понять, скопируйте его на пустой лист.

Копирование примера

21. Выделите пример в этом разделе. При копировании примера в приложение Excel Web App
выполняйте копирование и вставку по одной ячейке за раз.

22. Нажмите сочетание клавиш CTRL+C.

23. Создайте пустую книгу или лист.

24. Выделите на листе ячейку A1 и нажмите сочетание клавиш CTRL+V. При работе в Excel Web App
повторите копирование и вставку для всех ячеек в примере.

25. Чтобы переключиться между просмотром результатов и просмотром формул, возвращающих эти
результаты, нажмите клавиши CTRL+` (апостроф) или на вкладке Формулы в группе Зависимости
формул нажмите кнопку Показать формулы.

A B
1 Продукт Количество
2
Бананы 38
3
4 Апельсины 25
5 Яблоки 41
6
Груши 40
7 Формула Описание (результат)
=ИНДЕКС(A2:B5;ПОИСКПОЗ("Груши";A2:A5;0);2 Поиск значения «Груши» в столбце A и возвращение
) соответствующего значения из столбца B (40).

Приведенная формула использует следующие аргументы.


Формула поиска значений в несортированном диапазоне

A2:B5: Весь диапазон, в котором осуществляется поиск значений.

ПОИСКПОЗ("Груши";A2:A5;0): Функция ПОИСКПОЗ определяет номер строки.

"Груши": Значение для поиска в столбце подстановки.

A2:A5: Столбец для поиска для функции ПОИСКПОЗ.

2: Столбец, из которого возвращается значение. 1 — это крайний левый столбец.

Дополнительные сведения об использовании этих функций см. в статьях Функция ИНДЕКС и Функция
ПОИСКПОЗ.

К НАЧАЛУ СТРАНИЦЫ

Поиск значений по вертикали в списке неизвестного


размера по точному совпадению

Для выполнения этой задачи используются функции СМЕЩ и ПОИСКПОЗ.

Данный метод целесообразно использовать при поиске данных в ежедневно обновляемом внешнем
диапазоне данных. Известна цена в столбце B, но неизвестно, сколько строк данных возвратит сервер, а
первый столбец не отсортирован в алфавитном порядке.

ПРИМЕР

Чтобы этот пример проще было понять, скопируйте его на пустой лист.

Копирование примера

26. Выделите пример в этом разделе. При копировании примера в приложение Excel Web App
выполняйте копирование и вставку по одной ячейке за раз.

27. Нажмите сочетание клавиш CTRL+C.

28. Создайте пустую книгу или лист.

29. Выделите на листе ячейку A1 и нажмите сочетание клавиш CTRL+V. При работе в Excel Web App
повторите копирование и вставку для всех ячеек в примере.

30. Чтобы переключиться между просмотром результатов и просмотром формул, возвращающих эти
результаты, нажмите клавиши CTRL+` (апостроф) или на вкладке Формулы в группе Зависимости
формул нажмите кнопку Показать формулы.

A B
1 Продукт Количество
2
Бананы 38
3
4 Апельсины 25
5 Яблоки 41
6
Груши 40
7 Формула Описание (результат)
=СМЕЩ(A1;ПОИСКПОЗ("Груши";A2:A5; Поиск значения «Груши» в столбце A и возвращение
0);1) соответствующего значения из столбца B (40).

Приведенная формула использует следующие аргументы.

A1: Левая верхняя ячейка диапазона, называемая начальной ячейкой.

ПОИСКПОЗ("Груши";A2:A5; 0): Функция ПОИСКПОЗ определяет номер строки под начальной ячейкой для

поиска искомого значения.

"Груши": Значение для поиска в столбце подстановки.

A2:A5: Столбец для поиска для функции ПОИСКПОЗ. Не включайте начальную ячейку в этот диапазон.

1: Число столбцов для поиска искомого значения, расположенных справа от начальной ячейки.

Функция ГПР
Показать все

Выполняет поиск значения в верхней строке таблицы или массива значений и возвращает значение того же
столбца в заданной строке таблицы или массива. Функция ГПР используется, когда сравниваемые значения
расположены в верхней строке таблицы данных, а возвращаемые — на несколько строк ниже. Если
сравниваемые значения находятся в столбце слева от искомых данных, следует использовать функцию ВПР.

Буква Г в аббревиатуре «ГПР» означает «горизонтальный».

Синтаксис

ГПР(искомое_значение;таблица ;номер_строки;интервальный_просмотр)

Искомое_значение — значение, которое требуется найти в первой строке таблицы. «Искомое_значение»


может быть значением, ссылкой или текстовой строкой.

Таблица — таблица с информацией, в которой производится поиск данных. Можно использовать ссылку
на интервал или имя интервала.
• Значения в первой строке аргумента «таблица» могут быть текстом, числами или логическими

значениями.

• Если аргумент «интервальный_просмотр» имеет значение ИСТИНА, то значения в первой строке

аргумента «таблица» должны быть расположены в возрастающем порядке: ...-2, -1, 0, 1, 2, ..., A-Z, ЛОЖЬ,

ИСТИНА; в противном случае функция ГПР может выдать неправильный результат. Если же аргумент

«интервальный_просмотр» имеет значение ЛОЖЬ, сортировка для аргумента «таблица» не обязательна.

• Текстовые строки считаются эквивалентными независимо от регистра букв.

• Сортировка значений в порядке возрастания, слева направо. Дополнительные сведения см. в

разделе Сортировка данных.

Номер_строки — номер строки в массиве «таблица», из которой будет возвращено сопоставляемое


значение. Если значение аргумента «номер_строки» равно 1, то возвращается значение из первой строки
аргумента «таблица», если оно равно 2 — из второй строки и т. д. Если значение аргумента «номер_строки»
меньше 1, функция ГПР возвращает значение ошибки #ЗНАЧ!; если оно больше, чем количество строк в
аргументе «таблица», возвращается значение ошибки #ССЫЛ!.

Интервальный_просмотр — логическое значение, которое определяет, какое соответствие должна


искать функция ГПР — точное или приблизительное. Если этот аргумент имеет значение ИСТИНА или
опущен, возвращается приблизительно соответствующее значение; при отсутствии точного соответствия
возвращается наибольшее из значений, меньших, чем «искомое_значение». Если этот аргумент имеет
значение ЛОЖЬ, функция ГПР ищет точное соответствие. Если оно не найдено, возвращается значение
ошибки #Н/Д.

Замечания

• Если ГПР не может найти «искомое_значение» и аргумент «интервальный_просмотр» имеет

значение ИСТИНА, используется наибольшее из значений, меньших, чем «искомое_значение».

• Если значение аргумента «искомое_значение» меньше, чем наименьшее значение в первой строке

аргумента «таблица», функция ГПР возвращает значение ошибки #Н/Д.

• Если аргумент «интервальный_просмотр» имеет значение ЛОЖЬ и аргумент «искомое_значение»

является текстом, в аргументе «искомое_значение» можно использовать подстановочные знаки:

вопросительный знак (?) и звездочку (*). Вопросительный знак соответствует любому знаку; звездочка —

любой последовательности знаков. Чтобы найти какой-либо из самих этих знаков, следует поставить перед

ними знак тильды (~).

Пример

Чтобы этот пример проще было понять, скопируйте его на пустой лист.

Копирование примера
• Создайте пустую книгу или лист.

• Выделите пример в разделе справки.

• Нажмите сочетание клавиш CTRL+C.

• На листе выделите ячейку A1 и нажмите сочетание клавиш CTRL+V.

• Чтобы переключиться между просмотром результатов и просмотром формул, возвращающих эти

результаты, нажмите сочетание клавиш CTRL+` (тупое ударение) или на вкладке Формулы в группе

Зависимости формул нажмите кнопку Отобразить формулы.

A B C
1 Оси Подшипники Болты
2 4 4 9
3 5 7 10
4 6 8 11

Формула Описание (результат)


=ГПР("Оси";A1:C4;2;ИСТИНА) Поиск слова «Оси» в строке 1 и возвращение значения из
строки 2, находящейся в том же столбце (4)
=ГПР("Подшипники";A1:C4;3;ЛОЖЬ) Поиск слова «Подшипники» в строке 1 и возвращение
значения из строки 3, находящейся в том же столбце (7)
=ГПР("П";A1:C4;3;ИСТИНА) Поиск буквы «П» в строке 1 и возвращение значения из
строки 3, находящейся в том же столбце. Поскольку «П»
не является точным совпадением, возвращается
ближайшее из меньших значений: «Оси» (5)
=ГПР("Болты";A1:C4;4) Поиск слова «Болты» в строке 1 и возвращение значения
из строки 4, находящейся в том же столбце (11)
=ГПР(3; Поиск числа 3 в строке 1 массива констант и
{1;2;3:"a";"b";"c";"d";"e";"f"};2;ИСТИНА) возвращение значения из строки 2, находящейся в том же
столбце. (c)

Функции Е
Показать все

В этой статье описан синтаксис формулы и использование функциий Е в Microsoft Office Excel.

Описание

Каждая из этих функций проверяет указанное значение и возвращает в зависимости от него значение
ИСТИНА или ЛОЖЬ. Например, функция ЕПУСТО возвращает логическое значение ИСТИНА, если
проверяемое значение является ссылкой на пустую ячейку; в противном случае возвращается логическое
значение ЛОЖЬ.

Функции Е используются для получения сведений о значении перед выполнением с ним вычисления или
другого действия. Например, для выполнения другого действия при возникновении ошибки можно
использовать функцию ЕОШИБКА в сочетании с функцией ЕСЛИ:

=ЕСЛИ(ЕОШИБКА(A1); "Произошла ошибка."; A1 * 2)


Эта формула проверяет наличие ошибки в ячейке A1. При возникновении ошибки функция ЕСЛИ возвращает
сообщение "Произошла ошибка." Если ошибки отсутствуют, функция ЕСЛИ вычисляет произведение A1*2.

Синтаксис

ЕПУСТО(значение)

ЕОШ(значение)

ЕОШИБКА(значение)

ЕЛОГИЧ(значение)

ЕНД(значение)

ЕНЕТЕКСТ(значение)

ЕЧИСЛО(значение)

ЕССЫЛКА(значение)

ЕТЕКСТ(значение)

Функции Е имеют аргументы, указанные ниже.

• Значение. Обязательный аргумент. Значением этого аргумента может быть пустая ячейка,

значение ошибки, логическое значение, текст, число, ссылка на любой из перечисленных объектов или имя

такого объекта.

ФУНКЦИЯ ВОЗВРАЩАЕТ ЗНАЧЕНИЕ ИСТИНА, ЕСЛИ


ЕПУСТО Аргумент «значение» ссылается на пустую ячейку
ЕОШ Аргумент «значение» ссылается на любое значение ошибки, кроме #Н/Д
ЕОШИБКА Аргумент «значение» ссылается на любое значение ошибки (#Н/Д, #ЗНАЧ!, #ССЫЛ!, #ДЕЛ/0!, #ЧИСЛО!, #ИМЯ? или
#ПУСТО!)
ЕЛОГИЧ Аргумент «значение» ссылается на логическое значение
ЕНД Аргумент «значение» ссылается на значение ошибки #Н/Д (значение недоступно)
ЕНЕТЕКСТ Аргумент «значение» ссылается на любой элемент, который не является текстом. (Обратите внимание, что функция
возвращает значение ИСТИНА, если аргумент ссылается на пустую ячейку.)
ЕЧИСЛО Аргумент «значение» ссылается на число
ЕССЫЛКА Аргумент «значение» ссылается на ссылку
ЕТЕКСТ Аргумент «значение» ссылается на текст

Замечания

• Аргументы в функциях Е не преобразуются. Любые числа, заключенные в кавычки, воспринимаются

как текст. Например, в большинстве других функций, требующих числового аргумента, текстовое значение

"19" преобразуется в число 19. Однако в формуле ЕЧИСЛО("19") это значение не преобразуется из текста

в число, и функция ЕЧИСЛО возвращает значение ЛОЖЬ.


• С помощью этих функций удобно проверять результаты вычислений в формулах. Комбинируя эти

функции с функцией ЕСЛИ, можно находить ошибки в формулах (см. приведенные ниже примеры).

Пример 1

Чтобы лучше понять этот пример, скопируйте его на пустой лист.

Копирование примера

• Выделите пример в этом разделе. При копировании примера в приложение Excel Web App

выполняйте копирование и вставку по одной ячейке за раз.

• Нажмите сочетание клавиш CTRL+C.

• Создайте пустую книгу или лист.

• Выделите на листе ячейку A1 и нажмите сочетание клавиш CTRL+V. При работе в Excel Web App

повторите копирование и вставку для всех ячеек в примере.

• Чтобы переключиться между просмотром результатов и просмотром формул, возвращающих эти

результаты, нажмите клавиши CTRL+` (апостроф) или на вкладке Формулы в группе Зависимости

формул нажмите кнопку Показать формулы.

A B C
1 Формула Описание Результат
2 =ЕЛОГИЧ(ИСТИНА) Проверяет, является ли значение ИСТИНА логическим ИСТИНА

=ЕЛОГИЧ("ИСТИНА") Проверяет, является ли значение "ИСТИНА" логическим ЛОЖЬ


3
4 =ЕЧИСЛО(4) Проверяет, является ли значение 4 числом ИСТИНА

5 =ЕССЫЛКА(G8) Проверяет, является ли значение G8 допустимой ссылкой ИСТИНА

=ЕССЫЛКА(XYZ1) Проверяет, является ли значение XYZ1 допустимой ссылкой ЛОЖЬ


6

Пример 2

Чтобы лучше понять этот пример, скопируйте его на пустой лист.

Копирование примера

• Выделите пример в этом разделе. При копировании примера в приложение Excel Web App

выполняйте копирование и вставку по одной ячейке за раз.

• Нажмите сочетание клавиш CTRL+C.


• Создайте пустую книгу или лист.

• Выделите на листе ячейку A1 и нажмите сочетание клавиш CTRL+V. При работе в Excel Web App

повторите копирование и вставку для всех ячеек в примере.

• Чтобы переключиться между просмотром результатов и просмотром формул, возвращающих эти

результаты, нажмите клавиши CTRL+` (апостроф) или на вкладке Формулы в группе Зависимости

формул нажмите кнопку Показать формулы.

A B C
1 Данные
2 Золото
3 Регион1
4 #ССЫЛ!
5 330,92
6 #Н/Д
7 Формула Описание Результат
8 =ЕПУСТО(A2) Проверяет, является ли ячейка C2 пустой ЛОЖЬ

=ЕОШИБКА(A4) Проверяет, является ли значение в ячейке A4 (#ССЫЛ!) значением ошибки ИСТИНА


9
=ЕНД(A4) Проверяет, является ли значение в ячейке A4 (#ССЫЛ!) значением ошибки #Н/Д ЛОЖЬ
10 =ЕНД(A6) Проверяет, является ли значение в ячейке A6 (#Н/Д) значением ошибки #Н/Д ИСТИНА

11 =ЕОШ(A6) Проверяет, является ли значение в ячейке A6 (#Н/Д) значением ошибки ЛОЖЬ

12 =ЕЧИСЛО(A5) Проверяет, является ли значение в ячейке A5 (330,92) числом ИСТИНА

=ЕТЕКСТ(A3) Проверяет, является ли значение в ячейке A3 ("Регион1") текстом ИСТИНА


13

14