Вы находитесь на странице: 1из 18

Architectural Engineering Calculations

Discipline Type Description Web Ref: By


Acoustic Load Reverberation Time MC Squared Ching p228-232 JEM
Architecture Load Building Gross & $ from Net Arizona State JEM
Architecture Load Building Occupancy or Size Estimate Butler 58-59 JEM
Architecture Load Building Size JEM
Electrical Load Building Watts Required Estimate Ching 74-79 JEM
HVAC Sizing Air Flow Required & Duct Sizing Online Calc Ching 117-127 JEM
HVAC Load Basic Wall Conduction Ching 117-127 JEM
HVAC Load Infiltration and Ventilation Heat Load JEM
HVAC Sizing Seasonal Fuel Usage and Cost JEM
Lighting Load Lighting Fixture Requirements Ching 142-150 JEM
Plumbing Load Building Water Requirements Butler 584 JEM
Properties Conversion Factors JEM
Properties Material Properties JEM
Structure Load Floor Load Estimates Ching 238-245 JEM
Structure Stress Simple Beam - Stress & Deflection Ching 238-245 JEM
Structure Load Tributary Area Load Estimate Ching 238-245 JEM
Workbook Contributors JEM
Workbook Future Work JEM
Workbook Revision History JEM
This spreadsheet gives a number of basic Architectural Engineering (AE) calculations to allow initial quick estimates of loads and sizes for some
of the major systems. It is a work in progress and will be updated and corrected. It is not exact and should not be used for a building after initial
estimates. Use the professional-level programs for that purpose.

The Calculation column shows how the cell was calcuated using named variables - it should help you understand the logic. In most cases it's just
the application of basic math and physics although a few formulae are empirically derived. The hard part is often the units - which are carefully
shown.
Be sure to look at the "comments" - usually in the "input" column or the description column on this page - you see them by putting the cursor
over any cell that has a small red triangle in the upper right corner. They will explain meanings and give typical values.

- To use it click on the hyperlink to the calculation you're interested in (you may make suggestions for future ones on the "FutureWork" sheet).
- I n each worksheet the white boxes are ones you're intended to modify - "reasonable" default values are provided.
- You may "unprotect" the workbook and modify anything you wish.
- The "Return to Index" button will bring you back to this sheet.
- Note the "grouping" indicators at the top of each sheet. By clicking on the "1" or the horizontal line you may hide the calculations - probably
better for printing.

Users are urged to make corrections and additions and send the revised sheet back to J. Mitchell.
246684947.xls.ms_office - Index - Printed 10/7/2014 5:52 AM - p.1 of 18
Architecture Calculations
Gross Area & Cost from Net
Input Value Units Calculation User Comment
Allocation Offices 4,000 SF 4000
Allocation Meeting Room 2,600 SF =4*400 +1*1000
Allocation Storage 1,500 SF 1500
Allocation Eating Area 1,250 SF =50*25
Allocation Lobby 400 SF 400
Allocation Work Area 6,000 SF =40*150
Allocation Athletic Area 1,200 SF =30*40
Allocation Mechanical Electrical 1,500 SF =1500
Circulation & Structure Factor 32%
Building Cost Per SF 130 $ $/SF
Named Areas Total 18,450 SF =SUM(C6:C13)
Circulation & Structure 5,904 SF =Named_Areas_Total*Circulation___Structure_Factor
Building Gross Area 24,354 SF =Named_Areas_Total+Circulation___Structure
Building Cost 3,200,000 $ $ =ROUND(Building_Gross_Area*Building_Cost_Per_SF,-5)
CircStr Percent of Gross 24% =Circulation___Structure/Building_Gross_Area
Building Efficiency 76% =Named_Areas_Total/Building_Gross_Area
Building Gross Size - Measured
Input Value Units Calculation
Length Floor 1 80.0 Ft
Width Floor 1 60.0 Ft
Height to Next Floor 1 11.0 Ft
Length Floor 2 80.0 Ft
Width Floor 2 60.0 Ft
Height to Next Floor 2 11.0 Ft
Length Floor 3 80.0 Ft
Width Floor 3 60.0 Ft
Height to Next Floor 3 11.0 Ft
Length Floor 4 80.0 Ft
Width Floor 4 60.0 Ft
Height to Next Floor 4 11.0 Ft
Area Floor 1 4,800 SF =Length_Floor_1*Width_Floor_1
Area Floor 2 4,800 SF =Length_Floor_2*Width_Floor_2
Area Floor 3 4,800 SF =Length_Floor_3*Width_Floor_3
Area Floor 4 4,800 SF =Length_Floor_4*Width_Floor_4
Total Area 19,200 SF =SUM(C51:C54)
Volume Floor 1 52,800 CF =Area_Floor_1*Height_to_Next_Floor_1
Volume Floor 2 52,800 CF =Area_Floor_2*Height_to_Next_Floor_2
Volume Floor 3 52,800 CF =Area_Floor_3*Height_to_Next_Floor_3
Volume Floor 4 52,800 CF =Area_Floor_4*Height_to_Next_Floor_4
Total Volume 211,200 CF =SUM(C57:C60)
Building Occupancy Estimate
Input Value Units Calculation
OC Building Type Office
Oc SF per Occupant 160 SF/Occ
Oc Building Gross Area 19,200 SF
When designing a building a critical number is the building sizebecause it affects both the building cost and issues like
siting the building and zoning coverage requirements. While this number can be determined a number of ways one
"usual" starting point is to add up the individual areas for each "function" that must happen in the building - this
produces the "Named Areas Total". The calculation shown takes some typical functions (be sure to check the comments)
then shows how to determine the Building Gross Area, and thus the cost.
Calculating the total Area and Volume is straightforward. You can add as many more floors or pieces of floor as you
wish.
The "Height to Next Floor" is often called the "Floor-to-Floor" height.
Function Breakdown
Allocation Offices
Allocation Meeting Room
Allocation Storage
Allocation Eating Area
Allocation Lobby
Allocation Work Area
Allocation Athletic Area
Allocation Mechanical
Electrical
246684947.xls.ms_office - Architecture - Printed 10/7/2014 5:52 AM - p.2 of 18
Oc Number of Occupants 120 Occupants =ROUND(Oc_Building_Gross_Area/Oc_SF_per_Occupant,0)
Oc Known Occupants 120 Occupants
Oc Building Size from Occupants 19,200 SF =ROUND(Oc_Known_Occupants*Oc_SF_per_Occupant,-2)
Knowing how many people will be in a building is important in many other calculations (HVAC and Plumbing
particularly). This calculation assumes that you know the building gross size and want to know how many people it will
accommodate for a particular use.

You can go the other direction equally well.
246684947.xls.ms_office - Architecture - Printed 10/7/2014 5:52 AM - p.3 of 18
Structures Calculations
Floor Load Estimates
Input Value Units Calculation User Comment
Space Width 20 Ft
Space Length 35 Ft
Space Floor to Floor 12 Ft
Space Floor Thickness 8 Inches
Max Furniture Weight 2,400 Lb =12*200
Max Floor Equipment Weight 2,400 Lb =4*600
Max People Weight 4,000 Lb =20*200
Built-In Cabinet Weight 8,000 Lb =400*20
Hung Equipment Weight 1,600 Lb =4*400
Floor Weight per CF 150 Lb/CF =150
Ceiling Weight per SF 3 Lb/SF 3
Partition Weight per SF Vertical Face 5 Lb/SFV =ROUND(((60*2)+(4*10))/(4*8),0)
Space Area 700 SF =Space_Width*Space_Length
Space Volume 8,400 CF =Space_Area*Space_Floor_to_Floor
Space Perimeter 110 LF =(2*Space_Width)+(2*Space_Length)
Partition Area 1,320 SF =Space_Perimeter*Space_Floor_to_Floor
Built-In Equipment Weight 9,600 Lb =Built_In_Cabinet_Weight+Hung_Equipment_Weight
Floor Assembly Weight 70,000 Lb =Space_Area*(Space_Floor_Thickness/12)*Floor_Weight_per_CF
Ceiling Assembly Weight 2,100 Lb =Space_Area*Ceiling_Weight_per_SF
Partition Weight 6,600 Lb =Partition_Area*Partition_Weight_per_SF_Vertical_Face
Live Load Weight 8,800 Lb =Max_Furniture_Weight+Max_Floor_Equipment_Weight+Max_People_Weig
Dead Load Weight 88,300 Lb =SUM(C23:C26)
Total Load 97,100 Lb =Live_Load_Weight+Dead_Load_Weight
PSF Live Load 13 Lb/SF =Live_Load_Weight/Space_Area
PSF Dead Load 126 Lb/SF =Dead_Load_Weight/Space_Area
PSF Total Load 139 Lb/SF =Total_Load/Space_Area
Total Load/CF 12 Lb/CF =Total_Load/Space_Volume
Tributary Area Load Estimates
Input Value Units Calculation
Trib Length Beam 24 Ft
Trib Width to Next Beam on Right 8 Ft
Trib Width to Next Beam on Left 10 Ft
Trib Floor Thickness Estimated 6 in
Trib Beam Width Estimated 10 in
Trib Beam Depth Estimated 18 in =Trib_Length_Beam*3/4
Trib Uniform Floor Live Load 50 Lb/SF
Trib Wall Height over Beam 11.5 Ft
Trib Wall Material Thickness over Beam 8.5 In
Trib Density Floor Material 135 Lb/CF
Trib Density Wall Material 90 Lb/CF
Trib Width Tributary Area 9 Ft =Trib_Width_to_Next_Beam_on_Right/2+Trib_Width_to_Next_Beam_on_Le
Trib Floor Slab Volume 108 CF =Trib_Width_Tributary_Area*Trib_Length_Beam*(Trib_Floor_Thickness_Est
imated/12)
Trib Wall Volume Resting on Beam 195.5 CF =Trib_Length_Beam*Trib_Wall_Height_over_Beam*(Trib_Wall_Material_Th
ickness_over_Beam/12)
Trib Beam Volume 30 CF =Trib_Length_Beam*(Trib_Beam_Width_Estimated/12)*(Trib_Beam_Depth_
Estimated/12)
Trib Floor Slab Load per Foot Beam 608 Lbs/LF =Trib_Floor_Slab_Volume*Trib_Density_Floor_Material/Trib_Length_Beam
Trib Beam Load per foot 169 Lbs/LF =Trib_Beam_Volume*Trib_Density_Floor_Material/Trib_Length_Beam
Trib Wall Over Beam Load per foot 730 Lbs/LF =ROUND(Trib_Wall_Volume_Resting_on_Beam*Trib_Density_Wall_Materia
l/Trib_Length_Beam,-1)
Trib Live Load per foot 450 Lbs/LF =ROUND(Trib_Width_Tributary_Area*Trib_Uniform_Floor_Live_Load,-1)
The most basic task in structural analysis is to find out how much load is applied to a building. This calculates the "gravity" load for a given area -
typically a building "bay" bounded by four columns or a "tributary area" spanning from the midpoint of one bay to the midpoint of the next and the
full length of the bay.

A basic distinction is between "live" and "dead" load. It's much easier to predict the "dead" than the live load because the designer has control over
it whereas they have to guess at the worst case for live load.

This calculation is a good approximation - but should not beused for a real design. It does NOT take into account factors of safety, code
requirements and other important ingredients. Take the structures class first.

Note how very much bigger the dead load is than the live load in most cases.
246684947.xls.ms_office - Structure - Printed 10/7/2014 5:52 AM - p.4 of 18
Trib Subtotal Dead Load per foot 1,510 Lbs/LF =ROUND(Trib_Floor_Slab_Load_per_Foot_Beam+Trib_Beam_Load_per_foo
t+Trib_Wall_Over_Beam_Load_per_foot,-1)
Trib Total Dead Load for Beam 36,200 Lbs =ROUND(Trib_Subtotal_Dead_Load_per_foot*Trib_Length_Beam,-2)
Trib Total Live Load for Beam 10,800 Lbs =ROUND(Trib_Live_Load_per_foot*Trib_Length_Beam,-2)
Trib Total Load for Beam 47,000 Lbs =ROUND(Trib_Total_Dead_Load_for_Beam+Trib_Total_Live_Load_for_Bea
m,-2)
Trib Symmetrical Reaction Load 23,500 Lbs =ROUND(Trib_Total_Load_for_Beam/2,-2)
Beam Stress & Deflection
Input Value Units Calculation
Case
Bm Beam Shape
B
Beam Geometry
Bm Beam Depth -"d" 20.00 inches
Bm Flange thickness 0.00 inches
Bm Flange width 2.63 inches
Bm Web Thickness 0.00 inches
Material Properties
Bm Modulus of Elasticity 1,600,000 psi
Bm Density 32 lbs/ft3
Bm Max Tension/Compression Stress 1,800 psi
Loading Geometry
Bm Beam Length - "L" 20.00 ft
Bm Beam Spacing - "s" 18.00 in
Bm Point Load1 X coord. - "Px1" 5.00 ft
Bm Point Load2 X coord.. - "Px2" 10.00 ft
Live Loading
Bm Uniform Load - "w" 80 lb/SF
Bm Point Load 1 - "P1" 500 lb
Bm Point Load 2 - "P2" 500 lb
Bm X Position Evaluated - "x" 10.00 ft
Beam Unit Properties - Calculated
Bm Web Height (calc) 20.00 inches =Bm_Beam_Depth-(2*Bm_Flange_thickness)
Bm Area 53 in2 =IF(Bm_Beam_Shape="I",2*(Bm_Flange_width*Bm_Flange_thickness)+
(Bm_Web_Thickness*Bm_Web_Height__calc),IF(Bm_Beam_Shape="B",Bm_
Flange_width*Bm_Beam_Depth,"error") )
Bm Moment of Inertia 1,750 in4 =IF(Bm_Beam_Shape="I",
(Bm_Web_Thickness*(Bm_Web_Height__calc^3)/12) + 2
*((Bm_Flange_thickness*Bm_Flange_width)*(Bm_Beam_Depth/2 -
Bm_Flange_thickness/2)^2),IF(Bm_Beam_Shape="B",(Bm_Flange_width*Bm
_Beam_Depth^3)/12,"error"))
Bm Weight/Foot of Length 12 lbs/linear-ft =(Bm_Area/144)*1*Bm_Density
Bm Section Modulus 175 in3 =Bm_Moment_of_Inertia/(Bm_Beam_Depth/2)
Beam Total Properties
Bm Beam Weight 233 Lbs =Bm_Beam_Length*Bm_Weight_Foot_of_Length
Bm Live Load Carried 2,400 Lbs =(Bm_Beam_Spacing/12)*Bm_Uniform_Load*Bm_Beam_Length
Bm Total Load Carried 2,633 Lbs =Bm_Beam_Weight+Bm_Live_Load_Carried
Bm Total Load/Ft 132 Lbs/Ft =(Bm_Uniform_Load*Bm_Beam_Spacing/12)+Bm_Weight_Foot_of_Length
Moments
Bm Moment UDL 6,583 ft-lbs =(Bm_Total_Load_Ft*Bm_X_Position_Used/2)*(Bm_Beam_Length-
Bm_X_Position_Used)
Bm Moment P1 1,250 ft-lbs =IF(Bm_X_Position_Used<Bm_Point_Load1_X_coord.,Bm_Point_Load_1*(B
m_Beam_Length-
Bm_Point_Load1_X_coord.)*Bm_X_Position_Used/Bm_Beam_Length,Bm_P
oint_Load_1*Bm_Point_Load1_X_coord.*(1-
Bm_X_Position_Used/Bm_Beam_Length))
When designing a beam (or girder) it's essential to find how much load is applied to it. To do so one must define the "tributary area" that the beam
is supporting. A conservative approach (neglecting the fact that girders at the end may carry some load too) defines the tributary area as the length
of the beam times the tributary width. The tributary width is best estimated as the distance from halfway to the beam on the left TO halfway to the
beam on the right. (Note that where the widths are constant then this is just the distance from one beam to the next - edges are where life usually
gets more interesting.)

In this case we've also assumed a wall resting on the beam - a fairly typical situation in buildings, especially for fire separation.

We've shown the load per linear foot (Lbs/LF) as well as total loads because that is often used in beam calculations.

This calculation is a good approximation - but should not beused for a real design. It does NOT take into account factors of safety, code
requirements and other important ingredients. Take the structures class first.

246684947.xls.ms_office - Structure - Printed 10/7/2014 5:52 AM - p.5 of 18
Bm Moment P2 2,500 ft-lbs =IF(Bm_X_Position_Used<Bm_Point_Load2_X_coord.,Bm_Point_Load_2*(B
m_Beam_Length-
Bm_Point_Load2_X_coord.)*Bm_X_Position_Used/Bm_Beam_Length,Bm_P
oint_Load_2*Bm_Point_Load2_X_coord.*(1-
Bm_X_Position_Used/Bm_Beam_Length))
Bm Total Moment at X 124,000 In-lbs =(Bm_Moment_UDL+Bm_Moment_P1+Bm_Moment_P2)*12
Stress Calculation
Bm Maximum Fiber Stress at X 709 psi =Bm_Total_Moment_at_X/Bm_Section_Modulus
Bm Less Than Allowable OK '=IF(Bm_Maximum_Fiber_Stress_at_X<Bm_Max_Tension_Compression_Stre
ss,"OK","Trouble")
Deflection Calculations
Bm Deflection due to UDL 0.169 in =(12^3)*((Bm_Total_Load_Ft*Bm_X_Position_Used)/(24*Bm_Modulus_of_
Elasticity*Bm_Moment_of_Inertia))*(Bm_Beam_Length^3 -
2*Bm_Beam_Length*Bm_X_Position_Used^2 + Bm_X_Position_Used^3)
Bm Deflection due to P1 0.035 in =(12^3)*(IF(Bm_X_Position_Used<Bm_Point_Load1_X_coord.,
((Bm_Point_Load_1*(Bm_Beam_Length-
Bm_Point_Load1_X_coord.)*Bm_X_Position_Used)/(6*Bm_Beam_Length*B
m_Modulus_of_Elasticity*Bm_Moment_of_Inertia) ) * (Bm_Beam_Length^2
-Bm_X_Position_Used^2-((Bm_Beam_Length-
Bm_Point_Load1_X_coord.)^2)), (
(Bm_Point_Load_1*(Bm_Beam_Length-
Bm_Point_Load1_X_coord.))/(6*Bm_Beam_Length*Bm_Modulus_of_Elastici
ty*Bm_Moment_of_Inertia)) * ( (Bm_Beam_Length/(Bm_Beam_Length-
Bm_Point_Load1_X_coord.))*((Bm_X_Position_Used-
Bm_Point_Load1_X_coord.)^3)
+Bm_X_Position_Used*(Bm_Beam_Length^2 - (Bm_Beam_Length-
Bm Deflection due to P2 0.051 in =(12^3)*(IF(Bm_X_Position_Used<Bm_Point_Load2_X_coord.,
((Bm_Point_Load_2*(Bm_Beam_Length-
Bm_Point_Load2_X_coord.)*Bm_X_Position_Used)/(6*Bm_Beam_Length*B
m_Modulus_of_Elasticity*Bm_Moment_of_Inertia) ) * (Bm_Beam_Length^2
-Bm_X_Position_Used^2-((Bm_Beam_Length-
Bm_Point_Load2_X_coord.)^2)), (
(Bm_Point_Load_2*(Bm_Beam_Length-
Bm_Point_Load2_X_coord.))/(6*Bm_Beam_Length*Bm_Modulus_of_Elastici
ty*Bm_Moment_of_Inertia)) * ( (Bm_Beam_Length/(Bm_Beam_Length-
Bm_Point_Load2_X_coord.))*((Bm_X_Position_Used-
Bm_Point_Load2_X_coord.)^3)
+Bm_X_Position_Used*(Bm_Beam_Length^2 - (Bm_Beam_Length-
Bm Deflection Total 0.256 in =Bm_Deflection_due_to_UDL+Bm_Deflection_due_to_P1+Bm_Deflection_d
ue_to_P2
Bm Deflection Ratio 937 :1 =(Bm_Beam_Length*12)/Bm_Deflection_Total
BEAM CALCULATI ONS
This document is prepared as a starting point for beam design It is important to realize that it is simplified for the sake of education. In particular:
- shear is ignored
- buckling is ignored
- all stresses are assumed in the plane of symmetry.
- the beam is assumed to be simply supported
- factors of safety are built into the allowable stress.

Warning: Thecalculation is only for point "x" along thebeam. You must explore multiple "x" values to determine the 'worst case'. For
symettrically loaded beams that is at the midpoint of the span, but for unsymettrical situations you must find the 'worst case' location. Excel's "solver"
can be very handy for this.

Reference: The specific terms used in this spreadsheet were derived from Timoshenko & Young - Elements of strength of Materials - 4th Edition
(1962).
A more recent reference (used in Drexel's courses) is: Gere & Timoshenko - Mechanics of Materials. - 3rd Edition 1990. The relevant chapter in that
book for fuller understanding of the equations used here is: Chapters 5 (Stresses) & 7 (Deflections).

246684947.xls.ms_office - Structure - Printed 10/7/2014 5:52 AM - p.6 of 18
HVAC Calculations
Conductive Heat Transfer Through a Wall & Roof
Input Value Units Calculation User Comment
Temperature Outside 14 DegF
Temperature Inside 68 DegF
Cd Building Length 40 Ft
Cd Building Wdith 30 Ft
Cd Building Number of Floors 3
Cd Floor-to-Floor Height 11 Ft
Cd Window Spacing along Wall 12 Ft
Single Window Ht 6 Ft
Single Window Width 5 Ft
Number of Windows 35 =ROUND(Cd_Building_Number_of_Floors*(2*(Cd_Building_Length/Cd_Win
dow_Spacing_along_Wall+Cd_Building_Wdith/Cd_Window_Spacing_along_
Wall)),0)
Insulation Thickness 2.5 in
R-Value Insulation 6 SF-DegF-Hr/BTU-in
R-Value Construction and Air Gaps 2 SF-DegF-Hr/BTU-in =1+1
R-Value Window 2 SF-DegF-Hr/BTU-in
Wall Length 140 Ft =2*(Cd_Building_Length+Cd_Building_Wdith)
Wall Height 33 Ft =Cd_Building_Number_of_Floors*Cd_Floor_to_Floor_Height
Delta-T -54 DegF =Temperature_Outside-Temperature_Inside
Area Wall with Windows 4,620 SF =Wall_Length*Wall_Height
Area Windows 1,050 SF =Number_of_Windows*(Single_Window_Ht*Single_Window_Width)
Area Roof 1,200 SF =Cd_Building_Length*Cd_Building_Wdith
Cd Building Area 3,600 SF =Area_Roof*Cd_Building_Number_of_Floors
Area Wall & Roof without Windows 4,770 SF =(Area_Wall_with_Windows-Area_Windows)+Area_Roof
R-Insulation 15 SF-DegF-Hr/BTU =R_Value_Insulation*Insulation_Thickness
R-Wall &Roof 17 SF-DegF-Hr/BTU =R_Insulation+R_Value_Construction_and_Air_Gaps
Heat Flow Q Wall & Roof -15,152 BTU/Hr =Area_Wall___Roof_without_Windows*Delta_T/R_Wall
Heat Flow Q Windows -28,350 BTU/Hr =Area_Windows*Delta_T/R_Value_Window
Total Conductive Heat Flow -43,502 BTU/Hr =Heat_Flow_Q_Wall+Heat_Flow_Q_Windows
-12,750 Watts =Total_Heat_Flow/BTU_Wt_Hr
Infiltration & Ventilation Heat Load
Input Value Units Calculation
Inf T Outside 14 DegF =Temperature_Outside
Inf T Inside 68 DegF =Temperature_Inside
Inf Building Area 3,600 SF =Cd_Building_Area
Inf Floor Height Average 11 Ft =Cd_Floor_to_Floor_Height
Inf Infiltration Air Changes / Hour 1.5 Air Change/Hour
Inf People In Building 9 =Inf_Building_Area/400
Inf CFM per Person 20 CFM/person
Inf Delta T -54 DegF =Inf_T_Outside-Inf_T_Inside
Inf Building Volume 39,600 CF =Inf_Building_Area*Inf_Floor_Height_Average
Inf Infiltration CF per Hour 59,400 CF/Hr =Inf_Building_Volume*Inf_Infiltratioin_Air_Changes___Hour
Inf Ventilation per Hour 10,800 CF/Hr =Inf_People_In_Building*Inf_CFM_per_Person*60
Inf Total Air Per Hour 70,200 CF/Hr =Inf_Ventilation_per_Hour+Inf_Infiltration_CF_per_Hour
Inf Heat Lost to Air Movement -68,519 BTU/Hr =Inf_Total_Air_Per_Hour*Properties!Air_Density*Properties!Air_Specific_He
at*Inf_Delta_T
In HVAC, as in structures, the most basic requirement is to calculate the "Loads" on a system. For HVAC the most important o f these is
the amount of Heat (Q) that the system must add to (heating) or remove from (cooling) a space.

In a real building you must take account of not only the heat flow through the windows, but also the air leakage and the amou nts of heat
added by the appliances, people and sunlight coming into the room. Once you understand the principles this is best done with a modeling
program like Energy-10 or the commercial programs by Carrier or Trane.

Nonetheless this approximation is quite good, especially for a heating situation - in the middle of winter with no one in the building at
night.
246684947.xls.ms_office - HVAC - Printed 10/7/2014 5:52 AM - p.7 of 18
-68234.4
Duct Sizing to Transfer Required Heat
Input Value Units Calculation
QNeed -112,020 BTU/hr =ROUND(Total_Heat_Flow+Inf_Heat_Lost_to_Air,-1)
TDuct 120 DegF
TRoom 68 DegF
Air Velocity In Duct 1,200 fpm
AspectRatio 1.5
DeltaT Delivery 52 DegF =(TDuct-TRoom)
Coeff - BTU per CFM Deg 1.08 BTU/(CFM Hr DegF) =ROUND(Properties!Air_Density*Properties!Air_Specific_Heat*Min_Hr,2)
Air Flow CFM 1,990 CFM =ROUND(ABS(QNeed/(Coeff___BTU_per_CFM_Deg*DeltaT_Delivery)),-1)
Area Needed 239 in2 =ROUND((Air_Flow_CFM/Air_Velocity_In_Duct)*SqIN_SF,0)
DiamRound 18 in =ROUNDUP(2*SQRT(Area_Needed/3.14159),0)
Rectangle ShortSide 14 in =ROUNDUP(EXP((LN((DiamRound/1.3)*((1+AspectRatio)^0.25)/(AspectRati
o^0.625)) )/ ((2*0.625)-0.25) ),0)
Rectangle LongSide 21 in =ROUND(Rectangle_ShortSide*AspectRatio,0)
AreaRect 294 in2 =ROUND(Rectangle_ShortSide*Rectangle_LongSide,0)
Seasonal Fuel Usage and Cost
Input Value Units Calculation
HDd Building Area 1,200 SF
HDd T Interior 68 Deg
HDd T Exterior Min 5 Deg
HDd Max Hourly Building Heat Transfer 19,288 BTU/Hr
HDd DDhAnnual 3,749 Deg-Day
Fuel Efficiencies
HDd Oil Efficiency 80%
HDd Gas Efficiency 85%
HDd Elect Resistance Efficiency 100%
HDd Heat Pump Coefficient 262%
Fuel Prices
HDd Cost Oil Per Gallon 1.10 $ $/Gal
HDd Cost Gas per CCF 0.88 $ $/CCF
HDd Cost Elect per KWH 0.130 $ $/KWH
HDd Building Constant 306 BTU/Hr-deg =ROUND(HDd_Max_Hourly_Building_Heat_Transfer / (HDd_T_Interior-
HDd_T_Exterior_Min),0)
HDd Season Heat Transfer 27,532,656 BTU/Yr =HDd_Building_Constant*HDd_DDhAnnual*24
HDd Season Heat Transfer Per Sq Ft 22,944 BTU/SF-Season =HDd_Annual_Heat_Transfer/HDd_Building_Area
Fuel Consumption
Hdd Gallons Oil 240 Gallons =ROUND(HDd_Annual_Heat_Transfer/(HDd_Oil_Efficiency
*Oil_Heat_Value),-1)
HDd CCFGas 310 CCF =ROUND(HDd_Annual_Heat_Transfer/(HDd_Gas_Efficiency
*Natural_Gas_Heat_Value*100),-1)
HDd KW Resistance 8,070 KWH =ROUND(HDd_Annual_Heat_Transfer/(HDd_Elect_Resistance_Efficiency
*(BTU_Wt_Hr*1000)),-1)
HDd KW Heat Pump 3,080 KWH =ROUND(HDd_Annual_Heat_Transfer/((BTU_Wt_Hr*1000)*HDd_Heat_Pu
mp_Coefficient),-1)
Once you know how much heat is required to be transferred you want to know how big the duct is that carries the air (the usua l fluid)
carrying the heat. This is a straightforward calculation that uses the velocity, density, and specific heat of the air to de termine how much
must flow to carry the required amount of heat. Once you know how much (CFM), the velocity then allows you to calculate the size of the
duct necessary to conduct it.

Note that the velocities in ducts are limited by two things - the noise the air makes in the duct and the friction of the air in the duct - the
slower the flow the less energy is lost in friction. In practical terms, that limits low velocity ducts to about 1,200FPM - which is about13
MPH. High velocity ducts operate about 3,000FPM (34MPH), but require special construction and more fan energy.

Note that the defaults tie this calculation to the conductive loss calculation above and the ventilation/infiltration calcula tion, but you can
change it to suit your own needs.
Heat is lost through movement of air in and out of a building, both intentional (ventilation) and unintentional (infilitration). When
calculating the heating or cooling load one must include this heat loss or gain as well.

This estimate is crude, but gives an approximation, better for small buildings than large ones, but a reasonable start for both.

Note that the defaults tie this calculation to the conductive loss calculation above, but you can change it to suit your own needs.
246684947.xls.ms_office - HVAC - Printed 10/7/2014 5:52 AM - p.8 of 18
Fuel Consumption Per SF
Hdd Gallons Oil Per SF 0.20 Gallons/SF-Season =Hdd_Gallons_Oil/HDd_Building_Area
HDd CCFGas Per SF 0.26 CCF/SF-Season =HDd_CCFGas/HDd_Building_Area
HDd KW Resistance Per SF 6.73 KWH/SF-Season =HDd_KW_Resistance/HDd_Building_Area
HDd KW Heat Pump Per SF 2.57 KWH/SF-Season =HDd_KW_Heat_Pump/HDd_Building_Area
Season Cost
HDd Oil Season Cost 264 $ =Hdd_Gallons_Oil*HDd_Cost_Oil_Per_Gallon
HDd Gas Season Cost 273 $ =HDd_CCFGas*HDd_Cost_Gas_per_CCF
HDd Elect Resistance Season Cost 1,053 $ =HDd_KW_Resistance*HDd_Cost_Elect_per_KWH
HDd Elect Heat Pump Season Cost 402 $ =HDd_KW_Heat_Pump*HDd_Cost_Elect_per_KWH
Season Cost Per SF
HDd Oil Season Cost per SF 0.22 $ $/SF =HDd_Oil_Season_Cost/HDd_Building_Area
HDd Gas Season Cost per SF 0.23 $ $/SF =HDd_Gas_Season_Cost/HDd_Building_Area
HDd Elect Resistance Season Cost per SF 0.88 $ $/SF =HDd_Elect_Resistance_Season_Cost/HDd_Building_Area
HDd Elect Heat Pump Season Cost per SF 0.33 $ $/SF =HDd_Elect_Heat_Pump_Season_Cost/HDd_Building_Area
When developing an HVAC system the designer is interested in two things.
- How big does the equipment have to be to take care of the worst case?
- How much is it going to cost to operate for the year (or season of heating or cooling)?

The worst case situation is estimated by calculating the loads on the house.
- For heating it is the "conduction load" of heat lost through walls, windows, roof and to a small extent the floor. One must include as
well the "infiltration load" - the heat necessary to warm air that enters from the outside either through intended ventilation or through
cracks.
- For cooling it is the "conduction load" plus the solar energy, plus the infiltration, plus the heat from people, equipment an d lights.

The "right" way to calculate the energy consumption is by a simulation using standard weather on an hour -by-hour basis. This requires
a complex program

For small buildings the Degree-Day method uses the Degree-Day number produced by the weather service and the "worst case"
calculation the designer has already performed to estimate the operating costs.

The weather bureau publishes both heating degree-day records and cooling degree day records. Both can be used to calculate the
246684947.xls.ms_office - HVAC - Printed 10/7/2014 5:52 AM - p.9 of 18
Lighting Calculations
Lighting Fixture Requirements Estimate
Input Value Units
Calculation
User Comment
Lighting Calculations
Lt1 Room Area 500 SF
Lt1 Lighting Level 50 Footcandles
Lt1 Lamp Type Semi-Direct Fluorescent
Lt1 Number of Lamps Per Luminaire 4
Lt1 Lumens Per Lamp 3,200 Manufacturer
Lt1 Watts Per Lamp 46 Manufacturer
Lt1 Watts Per Transformer 10 Average
Lt1 Maintenance Factor 0.67
Lt1 Coeff of Util 0.47 From Chart
Lt1 Efficacy - Lumens/Watt 70 Lumens/Watt =Lt1_Lumens_Per_Lamp/Lt1_Watts_Per_Lamp
Lt1 Area/Luminaire 81 SF/Luminaire=(Lt1_Number_of_Lamps_Per_Fixture*Lt1_Lumens_Per_Lamp*Lt1_Coeff_of_
Util*Lt1_Maintenance_Factor)/Lt1_Lighting_Level
Lt1 Number of Luminaires (rounded) 7 =ROUNDUP(Lt1_Room_Area/Lt1_Area_Luminaire,0)
Lt1 Watts/Luminaire 194 Watts/Luminaire =(Lt1_Number_of_Lamps_Per_Fixture*Lt1_Watts_Per_Lamp)+Lt1_Watts_Per_
Transformer
Lt1 Watt/SF 2.7 Watts/SF =Lt1_Number_of_Luminaires__rounded*Lt1_Watts_Luminaire/Lt1_Room_Area
Calculating the exact number of fixtures is a complex process best accomplished with a method called the "Zonal Cavity Method" or
even better with a simulation program. Nonetheless it's possible to get an approximation at the beginning of a project using a cruder
calculation such as the one given here.

Note that in the lighting world
A "fixture" is what the layperson would call a lamp - it's the device that holds the lamps.
A "lamp" is what the layperson would call a bulb - it's the device that actually produces the light.

Examples are given here for several different types of lamps The number of lamps possible is very great as is the number of different
fixtures. These are only representative.

Source Mechanical and Electrical Equipment for Buildings - 5th ed -P.760
246684947.xls.ms_office - Lighting - Printed 10/7/2014 5:52 AM - p.10 of 18
Electrical Calculations
Estimating Building Watts Required
Input Value Units Calculation
User Comment
Lighting - Area Requiring "Service" 2,000 SF
Lighting - Area Requiring Standard 10,000 SF
Lighting - Area Requiring "Intense" 2,000 SF
Lighting - Area Requring "Spotlight" 1,000 SF
Appliances - Area Requiring Minimal 500 SF
Appliances - Area Requiring Residential 300 SF
Appliances - Area Requiring Office 15,000 SF
Appliances - Area Requiring Intense 1,000 SF
HVAC - Area Requiring Ventilation Only 1,000 SF
HVAC - Area Requiring Heating Only - NonElectric Heat 1,000 SF
HVAC - Area Requiring Full Conditioning 15,000 SF
Lighting Watts/SF Service 0.5 WSF
Lighting Watts/SF Standard 1.25 WSF
Lighting Watts/SF Intense 2 WSF
Lighting Watts/SF Spotlight 4 WSF
Appliances Watts/SF Minimal 1 WSF
Appliances Watts/SF Residential 2.5 WSF
Appliances Watts/SF Office 5 WSF
Appliances Watts/SF Intense 15 WSF
HVAC Watts/SF Ventilation Only 0.4 WSF
HVAC Watts/SF Heating Only - NonElectric Heat 0.6 WSF
HVAC Watts/SF Full Conditioning 1.7 WSF
Lighting - Subtotal Area 15,000 SF =SUM(C6:C9)
Appliances - Subtotal Area 16,800 SF =SUM(C10:C13)
HVAC - Subtotal Area 17,000 SF =SUM(C14:C16)
Max Area - Use for PSF 17,000 SF =MAX(C29:C31)
Lighting - Service Watts 1,000 Watts =Lighting___Area_Requiring__Service*Lighting_Watts_SF_Service
Lighting - Standard Watts 12,500 Watts =Lighting___Area_Requiring_Standard*Lighting_Watts_SF_Standard
Lighting - "Intense" Watts 4,000 Watts =Lighting___Area_Requiring__Intense*Lighting_Watts_SF_Intense
Lighting - Area Requring "Spotlight" Watts 4,000 Watts =Lighting___Area_Requring__Spotlight*Lighting_Watts_SF_Spotlight
Appliances - Minimal Watts 250 Watts =Appliances___Area_Requiring_Minimal*Appliances_Watts_SF_Minimal
Appliances - Residential Watts 750 Watts =Appliances___Area_Requiring_Residential*Appliances_Watts_SF_Residential
Appliances - Office Watts 75,000 Watts =Appliances___Area_Requiring_Office*Appliances_Watts_SF_Office
Appliances - Intense Watts 15,000 Watts =Appliances___Area_Requiring_Intense*Appliances_Watts_SF_Intense
HVAC - Ventilation Only Watts 400 Watts =HVAC___Area_Requiring_Ventilation_Only*HVAC_Watts_SF_Ventilation_O
HVAC - Heating Only - NonElectric Heat Watts 600 Watts
=HVAC___Area_Requiring_Heating_Only*HVAC_Watts_SF_Heating_Only__
_NonElectric_Heat
HVAC - Full Conditioning Watts 25,500 Watts
=HVAC___Area_Requiring_Full_Conditioning*HVAC_Watts_SF_Full_Conditi
oning
Subtotal - Lighting Watts 21,500 Watts =SUM(C34:C37)
Subtotal - Appliance Watts 91,000 Watts =SUM(C38:C41)
Subtotal - HVAC Watts 26,500 Watts =SUM(C42:C44)
Total Estimated Watts 139,000 Watts =SUM(C46:C48)
Lighting WSF Average 1.3 WSF =Subtotal___Lighting_Watts/Max_Area___Use_for_PSF
Appliance WSF Average 5.4 WSF =Subtotal___Appliance_Watts/Max_Area___Use_for_PSF
HVAC WSF Average 1.6 WSF =Subtotal___HVAC_Watts/Max_Area___Use_for_PSF
Overall WSF Average 8.2 WSF =Total_Estimated_Watts/Max_Area___Use_for_PSF
This form is somewhat more detailed than is perhaps necessary, but it gives a reasonable sense of the variable loads for different
conditions and allows a rapid overall estimate.

To use it all you need to do is put in the SF for each of your uses.
You do NOT need to change the Watt/SF for each use, but they're left available if you have better information.

Note that normally the Area totals should be identical, but there may be some situations where differing is OK. I picked the
maximum as the most reasonable for calculating overall WSF numbers.

Many building loads are quoted in KiloWatts (KW) - Just divide by 1,000 to determine the KW
The transformer for a building is usually in KVA - which is close to the total KW. It is usually sized with a growth factor of 20% or
more.
Power Use In Building
Lighting WSF Average
Appliance WSF Average
HVAC WSF Average
246684947.xls.ms_office - Electrical - Printed 10/7/2014 5:52 AM - p.11 of 18
Plumbing Calculations
Building Water Requirements
Input Value Units Calculation User Comment
Wr Building Type Office
Wr Number Occupants 188 Occupants
Wr Average Demand/Occupant 15 Gals/Day-Occ
Wr Peak Water Demand/Occupant 0.09 Gals/Min-Occ
Wr Summer Design Temp for Location 94 DegF
Wr Special Requirements Average 0 Gals/Day
Wr Special Requirements Peak Gals/Min
Wr Average Water Demand 2,880 Gals/Day =ROUND(Wr_Number_Occupants*Wr_Average_Demand_Occupant*(1+0.0007
7*(Wr_Summer_Design_Temp_for_Location-
65))+Wr_Special_Requirements_Average,-1)
Wr Peak Water Demand 17 Gals/Min =ROUND(Wr_Number_Occupants*Wr_Peak_Water_Demand_Occupant*(1+0.0
00115*(Wr_Summer_Design_Temp_for_Location-
65))+Wr_Special_Requirements_Peak,0)
One of the first tasks in defining a plumbing system is to determine the overall requirements, both on average and at
a peak time. This is particularly important because one must check the service available to the building - either a
water "main" or a well. If these are not sufficient for the need then there is likely to be significant additional expense
to provide the necessary water.
- If the average daily Demand is greater than the supply then a new "main" or well must be provided.
- If the peak demand is greater than the "main" or well can supply, but the daily average is adequate, then a storage
system will be necessary.

246684947.xls.ms_office - Plumbing - Printed 10/7/2014 5:52 AM - p.12 of 18
Acoustic Calculations
Reverberation of Space
Input Value Units Calculation User Comment
Room Length Acoustic 150 Ft
Room Width Acoustic 80 Ft
Room Height Acoustic 50 Ft
Absorption Wall Front 0.1
Absorption Wall Sides 0.1
Absorption Wall Rear 0.1
Absorption Floor & Seats 0.9
Absorption Ceiling 0.1
Volume of room Acoustic 600,000 CF =Room_Length_Acoustic*Room_Width_Acoustic*Room_Height_Acoustic
Area Wall Front Acoustic 4,000 SF =Room_Width_Acoustic*Room_Height_Acoustic
Area Wall Rear Acoustic 4,000 SF =Room_Width_Acoustic*Room_Height_Acoustic
Area Wall Sides Acoustic 15,000 SF =2*Room_Length_Acoustic*Room_Height_Acoustic
Area Ceiling Acoustic 12,000 SF =Room_Length_Acoustic*Room_Width_Acoustic
Area Floor Acoustic 12,000 SF =Room_Length_Acoustic*Room_Width_Acoustic
Absorption Front Sabins 400 Sabins =Area_Wall_Front_Acoustic*Absorption_Wall_Front
Absorption Rear Sabins 400 Sabins =Area_Wall_Rear_Acoustic*Absorption_Wall_Rear
Absorption Sides Sabins 1,500 Sabins =Area_Wall_Sides_Acoustic*Absorption_Wall_Sides
Absorption Floor and Seats Sabins 10,800 Sabins =Area_Floor_Acoustic*C12
Absorption Ceiling Sabins 1,200 Sabins =Area_Ceiling_Acoustic*Absorption_Ceiling
Total Absorption Sabins 14,300 Sabins =SUM(C21:C25)
Reverberation Time 2.1 secs =0.049*Volume_of_room_Acoustic/Total_Absorption_Sabins
Suited for Music or Speech Music '=IF(Reverberation_Time>1.2,"Music","Speech")
Reverberation is the time for a sound (e.g. a hand clapping is a good test) to decrease by 60 decibels.

The reverberation time of larger spaces is an important characteristic because it strongly influences the type of use for which space is
suited. Spaces in which understanding speech is important (a large classroom for instance) want minimal reverberation because it will
confuse the audience's comprehension. For much music, on the other hand, a significant reverberation time (here defined as 1.2
seconds) causes the music to blend together in a pleasing manner.

For rooms in which electronic amplification is used the reverberation is important, but the amplification can often address shortcomings
if well designed.

Remember that other factors determine the actual character of the sound - this is only an approximation. In particular the frequency
composition of the sound and the specific shape of the space are extremely important and are not addressed here.
246684947.xls.ms_office - Acoustic - Printed 10/7/2014 5:52 AM - p.13 of 18
Conversion Factors Used in This Spreadsheet
Efunda = Excellent Reference
Category Converstion Units Conversion ValueAmt1 Units1 Eq1Result1 Units1R Amt2 Units2 Eq Result2 Units2R
Area SqIN/SF 144 1 SF = 144 SqIn 144 SqIn = 1 SF Square Foot
Power BTU/Wt-Hr 3.412 1 Watt = 3.412 BTU/Hr 3.412 BTU/Hr = 1 Watts
Power Watt/HSP 745.7 1 HSP = 745.7 Watts 1000 Watts = 1.34 Hsp
Time Min/Hr 60 1 Hr = 60 Min 60 Min = 1 Hr
Velocity FPM/MPH 0.011364 3000 FPM = 34.1 MPH 1 MPH = 88 FMP Feet Per Minute
246684947.xls.ms_office - ConversionFactors - Printed 10/7/2014 5:52 AM - p.14 of 18
Properties Used in Spreadsheet
Efunda = Excellent Reference
Category Property Value Units Comment
HVAC Air Density 0.075 Lb/CF
HVAC Air Specific Heat 0.241 BTU/Lb
HVAC Oil Heat Value 141,000 BTU/Gal Heat value of #2 oil - often used in houses
HVAC Natural Gas Heat Value 1050 BTU/ft3 Heat value of Natural Gas
246684947.xls.ms_office - Properties - Printed 10/7/2014 5:52 AM - p.15 of 18
Contributors
Initial Name Email Affiliation
JEM James E. Mitchell James.Mitchell@CoE.Drexel.edu Drexel University - Civil & Architectural Engineering
246684947.xls.ms_office - Contributors - Printed 10/7/2014 5:52 AM - p.16 of 18
Future Work
Update: 9/28/2002
Discipline Type Description Web Ref: By
Plumbing Load Fixture Units Ching 196-201
Plumbing Load Hot Water Sizing Ching 196-201
Plumbing Load Pipe Sizing from Fixture Units Ching 196-201
Here's where Additions to the calculations are proposed. When they're completed they'll be move to the main index page.

Users are urged to make corrections and additions and send the revised sheet back to J. Mitchell.
246684947.xls.ms_office - FutureWork - Printed 10/7/2014 5:52 AM - p.17 of 18
Revision History
Date Type Description Page By
10/21/2002 Calculation Corrected Error in Beam Calculation -
Wrong reference to beam length
Structure JEM
10/21/2002 Format Made formulas display on Structures -
Unprotected first sheet
Workbook JEM
9/29/2002 Addition Added Future Work Future Work JEM
9/29/2002 Addition Added Occupancy Calculation Architecture JEM
9/29/2002 Addition Added Revision History Revision History JEM
9/29/2002 Addition Infiltration Calculation & Degree Day Calc HVAC JEM
9/29/2002 Calculation Added Plumbing Calculation Plumbing JEM
9/29/2002 Format Revised Format to Make Printer Friendly Workbook JEM
9/27/2002 Format Applied background and standardized Workbook JEM
9/15/2002 Start Began Spreadsheet Workbook JEM
Lists the revisions to this workbook with the page affected and th
246684947.xls.ms_office - RevisionHistory - Printed 10/7/2014 5:52 AM - p.18 of 18

Вам также может понравиться