UNIVERSIDAD DE EL SALVADOR

FACULTAD DE INGENIERA Y ARQUITECTURA

ESCUELA DE INGENIERA ELCTRICA
ANLISIS ELCTRICO I
CICLO I - 2017

Catedrtico: Ing. Gerardo Marvin Jorge Hernndez.

Instructor: Br. Cristian Antonio Aguilar Quintanilla.

Gua de Asignacin II: Circuitos de Primer Orden.

Asignacin 1. Determinar () y mostrar el pulso de control, realizar anlisis transitorio

desde 0 s hasta 200 ms (asignar ese periodo a las seales de control).

* Asignacin 1.
* Gua de simulacin II.
* AEL115 Ciclo I-2017.

* Fuentes de tensin independiente.

Vs 1 0 DC 12V
*Vs x 0 DC 0V AC 0V 0deg PULSE ( -2V 2V 0s 0s 0s 110ms 200ms )
*Vs1 1 x DC 12V
* Fuentes de control.
Vcontrol 4 0 DC 0V AC 0V 0deg PULSE ( 0V 1V 20ms 0ns 0ns 70ms 200ms )
* Resistencias.
R1 1 2 30kOhm
R2 2 3 150kOhm
R3 3 0 60kOhm
* Capacitores.
C1 3 0 0.5uF
* Interruptores.
S1 2 3 4 0 Switch
.model Switch SW ( VT=0.1V VH=0V RON=0.0001Ohm ROFF=10GOhm )
.control
* Anlisis Transitorio.
tran 0.1us 200ms 0ms 1us
plot V(3) V(4) vs (time*1k) xlabel 'Tiempo [ms]' ylabel 'Tensin[V]'
+title 'Tensin el capacitor'
destroy all
.endc
.end

Asignacin 2. Determinar (), calcular (3) y mostrar las seales de control de los
interruptores, realizar anlisis transitorio desde 0 s hasta 4 s (asignar ese periodo a las seales
de control).
* Asignacin 2.
* Gua de simulacin II.
* AEL115 Ciclo I-2017.

* Fuentes de tensin independiente.

Vx 4 5 DC 0V
* Fuentes de corriente independiente.
Is 0 1 DC 6A
* Fuentes de control.
Vcontrol1 6 0 DC 0V AC 0V 0deg PULSE ( 0V 1V 0s 0ns 0ns 4s 4s )
Vcontrol2 7 0 DC 0V AC 0V 0deg PULSE ( 0V 1V 2s 0ns 0ns 2s 4s )
* Resistencias.
R1 1 0 15Ohm
R2 2 3 10Ohm
R3 3 4 20Ohm
* Inductores.
L1 5 0 5H
* Interruptores.
S1 1 2 6 0 Switch
S2 3 4 7 0 Switch
.model Switch SW ( VT=0.1V VH=0V RON=0.0001Ohm ROFF=10e5Ohm )
.control
* Analisis Transitorio.
tran 1ms 4s 0s 0.1ms
plot i(Vx) V(6) V(7) xlabel 'Tiempo [s]' ylabel 'Corriente[A] y Tension [V]'
+title 'Corriente en el inductor (roja), Vcontrol1 (verde), Vcontrol2 (azul)'
destroy all
.endc
.end

Para t=3s i=3.589 [A]

Asignacin 3. Determine la tensin (), que se desarrolla en los terminales del interruptor
1 , considerando como nodo de referencia, al nodo donde se conecta la fuente de tensin ;
adems mostrar las seales de control de los interruptores por separado. Realizar anlisis
transitorio desde 0 s hasta 2 s (asignar ese periodo a las seales de control) y realizar un
Zoom para visualizar mejor el resultado de (); se sugiere realizar el Zoom entre 0.95
a 1.05 s.

* Asignacin 3.
* Gua de simulacin II.
* AEL115 Ciclo I-2017.

* Fuentes de tensin independientes.

Vs 1 0 DC 60V
* Fuentes de control.
Vcontrol1 6 0 DC 0V AC 0V 0deg PULSE ( 1V 0V 1s 0ns 0ns 2s 2s )
Vcontrol2 7 0 DC 0V AC 0V 0deg PULSE ( 0V 1V 1s 0ns 0ns 2s 2s )
* Resistencias.
R1 2 3 1kOhm
R2 2 4 100Ohm
R3 3 0 1kOhm
R4 5 0 60Ohm
* Inductores.
L1 4 5 1H
* Interruptores.
S1 1 2 6 0 Switch
S2 3 5 7 0 Switch
.model Switch SW ( VT=0.1V VH=0V RON=0.0001Ohm ROFF=10e5Ohm )
.control
* Anlisis Transitorio.
tran 10us 2s 0s 1us
plot V(1,2) xlabel 'Tiempo [s]' ylabel 'Tensin [V]'
+title 'Vab(t)'
plot V(6) V(7) xlabel 'Tiempo [s]' ylabel 'Tensin [V]'
+title 'Vcontrol1 (roja), Vcontrol2 (verde)'
destroy all
.endc
.end
Asignacin 4. Repetir la asignacin 1, pero con la modificacin de que a la seal de DC de
12 V ahora se le debe montar una seal pulsante 2 V con un ancho de pulso de 110 ms y
un periodo de 200 ms. Mostrar los grficos de (), () y ().