UNIVERSIDAD DE EL SALVADOR

FACULTAD DE INGENIERA Y ARQUITECTURA

ESCUELA DE INGENIERA ELCTRICA
ANLISIS ELCTRICO II
CICLO II - 2017

Catedrtico: Ing. Gerardo Marvin Jorge Hernndez.

Instructores: Br. Cristian Antonio Aguilar Quintanilla.
Br. Diego Fernando Guidos Espinoza.

Gua de Simulacin VII: Anlisis de Fourier, clculo de THD y Espectro de

Frecuencia.

Ejemplo. Se muestra un rectificador trifsico de onda completa controlado por SCR,

determinar la seal de tensin de salida y graficar los pulsos de control de las compuertas de
los SCR, determinar el THD de la seal de tensin de salida y con ayuda de Excel graficar el
espectro de frecuencias. Utilizar el SCR C106. Las bobinas en realidad corresponden a un
transformador, pero en este caso se designarn fuentes de tensin senoidales de 120 VRMS a
60 Hz por fase en secuencia CBA con referencia a cero grados para Van.

Cdigo en SPICE OPUS:

* Ejemplo.
* Gua de Simulacin VII.
* AEL215 Ciclo II-2017.

* Parmetros del circuito.

.param Vs = 120
.param f = 60
.param R = 0.5
.param L = 1.5m
.param Va = 0
.param Vy = 0
.param Vm = sqrt(2) * Vs
.param Pha = 0
.param Phb = -120
.param Phc = -240
.param angdis = 60
.param ret1 = angdis+30
.param ret2 = ret1+60
.param ret3 = ret2+60
.param ret4 = ret3+60
.param ret5 = ret4+60
.param ret6 = ret5+60
***********
***********
************************ Rectificador **************************************
***********
***********
Van 1 0 sin( 0 {Vm} {f} 0 0 {Pha} )
Vbn 2 0 sin( 0 {Vm} {f} 0 0 {Phb} )
Vcn 3 0 sin( 0 {Vm} {f} 0 0 {Phc} )
Va 1 4 DC {Va}
XT1 4 5 11 XC106D
XT2 0 10 3 XC106D
XT3 2 6 11 XC106D
XT4 0 8 4 XC106D
XT5 3 7 11 XC106D
XT6 0 9 2 XC106D
***********
***********
************************** Control de los SCR *******************************
***********
***********
Vg1 5 11 DC PULSE ( 0 10 {ret1/(360*f)} 1ns 1ns 100us {1/f} )
Vg3 6 11 DC PULSE ( 0 10 {ret3/(360*f)} 1ns 1ns 100us {1/f} )
Vg5 7 11 DC PULSE ( 0 10 {ret5/(360*f)} 1ns 1ns 100us {1/f} )
Vg4 8 4 DC PULSE ( 0 10 {ret4/(360*f)} 1ns 1ns 100us {1/f} )
Vg6 9 2 DC PULSE ( 0 10 {ret6/(360*f)} 1ns 1ns 100us {1/f} )
Vg2 10 3 DC PULSE ( 0 10 {ret2/(360*f)} 1ns 1ns 100us {1/f} )
***********
***********
******************************* Carga *************************************
***********
R 11 12 {R}
L 12 13 {L} Ic=0
Vy 13 0 {Vy}
***********
***********
************************ Subcircuito del SCR ********************************
***********
***********
* C106D SCR A G K MCE 7-17-95
*MCE 400V 4A pkg:TO-225AA
.SUBCKT XC106D 1 2 3
QP 6 4 1 POUT OFF
QN 4 6 5 NOUT OFF
RF 6 4 88.9MEG
RR 1 4 59.2MEG
RGK 6 5 1.12K
RG 2 6 46.2
RK 3 5 16.2M
DF 6 4 ZF
DR 1 4 ZR
DGK 6 5 ZGK
.MODEL ZF D (IS=1.6F IBV=900N BV=400 RS=13.3MEG)
.MODEL ZR D (IS=1.6F IBV=900N BV=533)
.MODEL ZGK D (IS=1.6F IBV=900N BV=6)
.MODEL POUT PNP (IS=1.6P BF=1 CJE=418P)
.MODEL NOUT NPN (IS=1.6P BF=100 RC=65M
+ CJE=418P CJC=83.7P TF=214N TR=68U)
.ENDS
***********
***********
.control
***********
***********
***********
************************ Anlisis Transitorio *********************************
***********
***********
tran 10ns 50ms 0ms 10us uic
*plot v(1) v(2) v(3)
*+xlabel 'Tiempo [s]' ylabel 'Tensin [V]' title 'Tensiones de entrada'
plot v(11) v(5,11) v(6,11) v(7,11) v(8,4) v(9,2) v(10,3)
+xlabel 'Tiempo [s]' ylabel 'Tensin [V]' title 'Tensin de salida
+y pulsos de compuertas'
*plot i(Vy)
*+xlabel 'Tiempo [s]' ylabel 'Corriente [A]' title 'Corriente en la carga'
fourier 180Hz v(11)
.endc
.end
 Espectro de frecuencia
100 92.2891
90
80
TENSION [V] 70 62.5469
60
50 41.8835
40
27.4552
30 20.4756
16.3416 13.6038
20 11.6559 10.199 9.06833
10
0
0 1 2 3 4 5 6 7 8 9
ARMONICA [N]

Tiempos de disparo para las compuertas de los SCR.