UNIVERSIDAD DE EL SALVADOR

FACULTAD DE INGENIERÍA Y ARQUITECTURA

ESCUELA DE INGENIERÍA ELÉCTRICA
ANÁLISIS ELÉCTRICO I
CICLO I - 2018

Catedrático: Ing. Gerardo Marvin Jorge Hernández.

Instructores: Br. Karen Amanda Agreda Rivas.
Br. Aura Lucia Mendoza Merlos.

Guía de Simulación I: Ley de Ohm, Kirchhoff y Amplificadores Operacionales.

Se tratará en primer lugar de los comandos básicos para la definición de circuitos,

enfocándose en el análisis de D. C., tanto para circuitos que contengan fuentes de voltaje y/o
corriente tanto independiente como dependientes. Se mostrarán los resultados de diversas
configuraciones implementadas con Amplificadores Operacionales (A.O).

Ejemplo 1. Determinar los voltajes de nodo 𝑣1 , 𝑣2 , 𝑣3 , 𝑣4 y el valor de la corriente 𝑖𝑏 .

Código en SPICE OPUS:

* Ejemplo 1.
* Guía de simulación I.
* AEL115 Ciclo I-2017.

* Fuentes de tensión independientes.

V1 1 0 DC 25
Vx 3 5 DC 0
* Fuentes de corriente independientes.
I1 0 3 DC 2
* Fuentes de tensión dependientes de tensión.
e1 2 3 4 0 5
* Fuentes de corriente dependientes de corriente.
f1 1 4 Vx 3
* Resistencias.
R1 1 2 10
R2 4 0 30
R3 4 5 20
.control
op
echo
echo Los voltajes en los nodos 1, 2, 3 y 4 son:
echo
print V(1)
print V(2)
print V(3)
print V(4)
echo
echo La corriente ib es:
echo
print i(Vx)
echo
.endc
.end
Ejemplo 2. Determinar los voltajes 𝑣1 y 𝑣2 , y las corrientes 𝑖𝑎 e 𝑖3 .

Código en SPICE OPUS:

* Ejemplo 2.
* Guía de simulación I.
* AEL115 Ciclo I-2017.

* Fuentes de tensión independientes.

V1 1 2 DC 50
Vx 6 0 DC 0
Vy 4 0 DC 0
* Fuentes de tensión dependientes de corriente
h1 2 0 Vx 30
* Resistencias.
R1 1 5 80
R2 1 5 20
R3 5 6 4
R4 2 4 40
R5 2 3 80
R6 3 0 80
.control
op
echo
echo Los voltajes v1 y v2 son:
echo
print V(1,5)
print V(3)
echo
echo Las corrientes ia e i3 son:
echo
print i(Vx)
print i(Vy)
echo
.endc
.end

Ejemplo 3. Realizar un Análisis de Barrido en DC para determinar el valor que deba tener RL
para que se le transfiera la máxima potencia posible.

Código en SPICE OPUS:

* Ejemplo 3.
* Guía de simulación I.
* AEL115 Ciclo I-2017.

* Fuentes de tensión independientes.

V1 1 0 DC 1
Vx 3 0 DC 0
* Resistencias.
R1 1 2 1k
R2 2 3 1
.control
* Análisis de barrido en DC.
dc r2 100 5k 100
let PR2=i(Vx)*V(2,3)
plot PR2*1Meg xlabel 'R2 [Ohm]' ylabel 'PR2 [uW]' title 'Característica PR2 vs R2'
.endc
.end

Haciendo uso del Zoom Box (presionando Z), se aprecia que el valor de R 2, para el cual
disipa la máxima potencia es 1 kΩ, para un valor de 250 µW.

Ejemplo 4. Para la configuración de amplificador inversor, si 𝑣𝑖𝑛 = 5 [𝑉𝐷𝐶 ], calcular el

voltaje de salida 𝑣𝑜𝑢𝑡 y la corriente en el resistor de 10 kΩ.

Código en SPICE OPUS:

* Ejemplo 4.
* Guía de simulación I.
* AEL115 Ciclo I-2017.

* Fuentes de tensión independientes.

V1 1 0 DC 5
Vx 2 3 DC 0
* Amplificadores Operacionales.
E1 4 0 0 3 10Meg
* Resistencias.
R1 1 2 10k
R2 3 4 25k
.control
op
echo
echo El voltaje de salida Vo es:
echo
print V(4)
echo
echo La corriente por la resistencia de 10k es:
echo
print i(Vx)
echo
.endc
.end
Ejemplo 5. Para la configuración mostrada calcular el voltaje de salida 𝑣𝑜𝑢𝑡 , si 𝑣𝑖𝑛1 =
6 [𝑉𝐷𝐶 ] y 𝑣𝑖𝑛2 = 4 [𝑉𝐷𝐶 ].

Código en SPICE OPUS:

* Ejemplo 5.
* Guía de simulación I.
* AEL115 Ciclo I-2017.

* Fuentes de tensión independientes.

V1 1 0 DC 6
V2 3 0 DC 4
* Amplificadores Operacionales.
E1 4 0 3 2 10Meg
* Resistencias.
R1 1 2 4k
R2 2 4 10k
.control
op
echo
echo El voltaje de salida Vo es:
echo
print V(4)
echo
.endc
.end
Ejemplo 6. Para la configuración mostrada, determinar la relación 𝑉𝑜 /𝑉𝑠 , donde 𝑉𝑠 = 1 [𝑉𝐷𝐶 ].

Código en SPICE OPUS:

* Ejemplo 6.
* Guía de simulación I.
* AEL115 Ciclo I-2017.

* Fuentes de tensión independientes.

Vs 1 0 DC 1
* Amplificadores Operacionales.
E1 3 0 1 2 10Meg
E2 5 0 0 4 10Meg
* Resistencias.
R1 2 0 10k
R2 2 3 50k
R3 3 4 100k
R4 4 5 100k
.control
op
echo
echo La ganancia de tensión Vo/Vs es:
echo
print V(3,5)/V(1)
echo
.endc
.end

Ejemplo 7. Para el siguiente circuito determinar el valor de 𝑣𝑜 e 𝑖𝑜 .

Código en SPICE OPUS:

* Ejemplo 7.
* Guía de simulación I.
* AEL115 Ciclo I-2017.

* Fuentes de tensión independientes.

V1 1 2 DC 6
Vx 5 6 DC 0
* Amplificadores Operacionales.
E1 6 0 0 4 10Meg
* Resistencias.
R1 1 3 10k
R2 3 2 30k
R3 1 4 30k
R4 2 4 10k
R5 3 5 30k
R6 3 0 10k
R7 5 0 30k
.control
op
echo
echo La tensión de salida Vo es:
echo
print V(5)
echo
echo La corriente io es:
print i(Vx)
echo
.endc
.end