Problema Bauxita Completo PDF

Sistemas de Transporte y Redes de Abastecimiento: Cadena de suministro de la bauxita 1
PROBLEMA DE LA BAUXITA: Ejemplo de una cadena de abastecimiento
Preparado por: Carlos Julio Vidal Holguín, Escuela de Ingeniería Industrial y

Estadística, Universidad del Valle
Fecha: Julio de 2005
Una compañía multinacional de aluminio tiene depósitos de bauxita (materia prima) en

tres lugares del mundo A, B y C. Tiene además cuatro plantas donde la bauxita se
convierte en alúmina (un producto intermedio), en lugares B, C, D y E. También tiene
plantas de esmaltado en los lugares D y E. El proceso de conversión de la bauxita en
alúmina es relativamente poco costoso. El esmaltado, sin embargo, es costoso puesto
que se requiere de un equipo electrónico especial. Una tonelada de alúmina produce 0.4
toneladas de aluminio terminado. Los datos siguientes están disponibles:
Minas de Costo de Capacidad anual Rendimiento

bauxita explotación de bauxita de alúmina
($/ton.) (ton.)
A 420 36000 6.0%
B 360 52000 8.0%
C 540 28000 6.2%
Conversión de Bauxita en Alúmina:
Costo Producción Capacidad anual Costo fijo anual

Planta ($/ton alúmina) procesamiento de la planta
de Bauxita de alúmina
B 330 40.000 $3,000,000
C 320 20.000 $2,500,000
D 380 30.000 $4,800,000
E 240 80.000 $6,000,000
Carlos Julio Vidal Holguín – Universidad del Valle – Escuela de Ingeniería Industrial y Estadística
Proceso de Esmaltado:
Costo Capacidad anual

Planta Procesamiento procesamiento
($/ton alúmina) de Alúmina (ton)
D 8500 4000
E 5200 7000
Las ventas anuales de aluminio terminado son de 1000 ton en la planta D y de 1200 ton
en la planta E.
Costos de transporte en $/ton de Bauxita:
DE HACIA B C D E
j= 1 2 3 4
A 1 400 2010 510 1920
i= B 2 10 630 220 1510
C 3 1630 10 620 940
Costos de transporte de la alúmina, en $/ton de alúmina:
DE HACIA D E
k= 1 2
B 1 220 1510
j= C 2 620 940
D 3 0 1615
E 4 1465 0
Los lingotes de producto terminado no se transportan entre D y E y viceversa. Formule y

resuelva un modelo de optimización para determinar la mejor configuración y diseño de la
cadena de abastecimiento presentada. Note que existe el problema de determinar cuáles
plantas de alúmina deben ser abiertas.
MODELO DE OPTIMIZACIÓN PROPUESTO
Wj
Xij B
Yjk
A
A T
C D l e
u r
B m m
i i
n n
D E i a
o d
C o
E
Minas de Plantas de Plantas de

Bauxita Alúmina Esmaltado
La figura muestra el esquema de la cadena de abastecimiento planteada. Se definen

entonces las siguientes variables de decisión:
Variables de Decisión
Xij = Ton/año de bauxita a transportar desde la mina i hacia la planta de alúmina j;
i = A, B, C; j = B, C, D, E.
Yjk = Ton/año de alúmina a transportar desde la planta de alúmina j hacia la planta

de esmaltado k; j = B, C, D, E; k = D, E.
Wj = 1, si la planta de alúmina j se abre; 0, de lo contrario; j = B, C, D, E.
Función Objetivo
Minimizar Costo Total Anual = Costo anual de explotación de bauxita
+ Costo anual de producción de alúmina
+ Costo anual de procesamiento de alúmina en las

plantas de esmaltado
+ Costo anual de transporte de bauxita desde las minas

hacia las plantas de alúmina
+ Costo anual de transporte de alúmina desde las

plantas de alúmina hacia las plantas de esmaltado
+ Costo fijo anual de las plantas de alúmina
Costo anual de explotación de bauxita ($/año):
Mina A : 420( X AB + X AC + X AD + X AE )
Mina B : 360( X BB + X BC + X BD + X BE )
Mina C : 540( X CB + X CC + X CD + X CE )
Costo anual de producción de alúmina ($/año):
Planta B : 330(Y BD + Y BE )
Planta C : 320(YCD + YCE )
Planta D : 380(Y DD + Y DE )
Planta E : 240(Y ED + Y EE )
Costo anual de procesamiento de alúmina en las plantas de esmaltado ($/año):
Planta D : 8500(Y BD + YCD + Y DD + Y ED )

Planta E : 5200(Y BE + YCE + Y DE + Y EE )
Costo anual de transporte desde las minas de bauxita hacia las plantas de alúmina
($/año):
Desde la mina A : 400 X AB + 2010 X AC + 510 X AD + 1920 X AE

Desde la mina B : 10 X BB + 630 X BC + 220 X BD + 1510 X BE
Desde la mina C : 1630 X CB + 10 X CC + 620 X CD + 940 X CE
Costo anual de transporte desde las plantas de alúmina hacia las plantas de esmaltado
($/año):
Hacia la planta D : 220Y BD + 620YCD + 1465Y ED

Hacia la planta E : 1510Y BE + 940YCE + 1615Y DE
Costo fijo anual de plantas de alúmina ($/año):
Planta B : 3,000,000W B
Planta C : 2,500,000W C
Planta D : 4,800,000W D
Planta E : 6,000,000W E
Restricciones:
1) Por capacidad anual de explotación de bauxita en cada mina (Ton de bauxita/año):
Mina A : X AB + X AC + X AD + X AE ≤ 36 ,000
Mina B : X BB + X BC + X BD + X BE ≤ 52 ,000
Mina C : X CB + X CC + X CD + X CE ≤ 28 ,000
Estas restricciones expresan que todo el flujo anual de bauxita que sale de cada mina
no puede exceder su capacidad anual de explotación.
2) Por capacidad anual de procesamiento de bauxita en cada planta de alúmina (Ton de

bauxita/año):
Planta B : X AB + X BB + X CB ≤ 40,000W B
Planta C : X AC + X BC + X CC ≤ 20,000W C
Planta D : X AD + X BD + X CD ≤ 30,000W D
Planta E : X AE + X BE + X CE ≤ 80,000W E
Nótese que no se puede recibir ningún flujo de bauxita desde las minas, si la planta
de alúmina correspondiente no ha sido abierta. Obsérvese también que las
anteriores restricciones, en combinación con el conjunto de restricciones (5) descrito
más adelante, aseguran que no se pueda despachar ninguna cantidad de alúmina
hacia las plantas de esmaltado, si la planta correspondiente no ha sido abierta.
3) Por capacidad anual de procesamiento de alúmina en cada planta de esmaltado (Ton

de alúmina/año):
Planta D : Y BD + YCD + Y DD + Y ED ≤ 4,000

Planta E : Y BE + YCE + Y DE + Y EE ≤ 7,000
Estas restricciones expresan que todo el flujo anual de alúmina que llega a cada
planta de esmaltado no puede exceder su capacidad anual de procesamiento de
alúmina.
4) Por ventas anuales de aluminio terminado en cada planta de esmaltado (Ton de

aluminio terminado/año):
Planta D : 0.4(Y BD + YCD + Y DD + Y ED ) = 1,000

Planta E : 0.4(Y BE + YCE + Y DE + Y EE ) = 1,200
Estas restricciones aseguran que la demanda anual proyectada en cada planta de

esmaltado se va a satisfacer en forma total. Nótese que se aplica el factor de
rendimiento de alúmina en aluminio terminado (0.4 toneladas de aluminio terminado
por cada tonelada de alúmina).
5) Por balance de masa en cada una de las plantas de alúmina:
Planta B : 0.060 X AB + 0.080 X BB + 0.062 X CB = Y BD + Y BE

Planta C : 0.060 X AC + 0.080 X BC + 0.062 X CC = YCD + YCE
Planta D : 0.060 X AD + 0.080 X BD + 0.062 X CD = Y DD + Y DE
Planta E : 0.060 X AE + 0.080 X BE + 0.062 X CE = Y ED + Y EE
Estas restricciones aseguran que la cantidad anual de bauxita que entra a cada
planta de alúmina, afectada por su correspondiente rendimiento para producir
alúmina, es igual a la cantidad anual de alúmina que sale de dicha planta hacia las
plantas de esmaltado.
6) Por límites en los valores de cada una de las variables:
X ij ≥ 0 ∀i , j
Y jk ≥ 0 ∀j , k
W j ∈ {0, 1} ∀j
Estas restricciones, denominadas comúnmente obvias, simplemente expresan la

naturaleza de las variables involucradas en el modelo. Las variables Xij y Yjk son
variables continuas que pueden tomar cualquier valor real positivo o cero, mientras
que las variables Wj son variables enteras que sólo pueden tomar valor 0 o 1,
denominadas variables binarias.
El modelo matemático para resolver el problema planteado comprende entonces

minimizar la función objetivo, sujeto a las restricciones anteriormente enunciadas. Al
simplificar la función objetivo y las restricciones, se obtiene el modelo de programación
lineal mixta mostrado en la página siguiente. Como puede observarse, este modelo
contiene 24 variables de decisión, de las cuales 4 son binarias y el resto son continuas,
y 15 restricciones (sin incluir las restricciones obvias).
Los modelos matemáticos de cadenas de abastecimiento reales pueden contener

decenas o cientos de miles de variables con decenas o cientos de miles de restricciones,
llegando incluso a millones de ellas. La dificultad para su solución eficiente depende
principalmente del número de variables enteras (binarias) involucradas en el modelo.
Minimizar Costo Total Anual (CTA) =
820 X AB + 2430 X AC + 930 X AD + 2340 X AE + 370 X BB + 990 X BC + 580 X BD + 1870 X BE

+ 2170 X CB + 550 X CC + 1160 X CD + 1480 X CE + 9050Y BD + 7040Y BE + 9440YCD + 6460YCE
+ 8880Y DD + 7195Y DE + 10205Y ED + 5440Y EE + 3,000,000W B + 2,500,000W C
+ 4,800,000W D + 6,000,000W E
Sujeto a:
X AB + X AC + X AD + X AE ≤ 36 ,000
X BB + X BC + X BD + X BE ≤ 52 ,000
X CB + X CC + X CD + X CE ≤ 28 ,000
X AB + X BB + X CB − 40,000W B ≤ 0
X AC + X BC + X CC − 20,000W C ≤ 0
X AD + X BD + X CD − 30,000W D ≤ 0
X AE + X BE + X CE − 80,000W E ≤ 0
Y BD + YCD + Y DD + Y ED ≤ 4,000
Y BE + YCE + Y DE + Y EE ≤ 7,000
0.4(Y BD + YCD + Y DD + Y ED ) = 1,000

0.4(Y BE + YCE + Y DE + Y EE ) = 1,200
0.060 X AB + 0.080 X BB + 0.062 X CB − Y BD − Y BE = 0

0.060 X AC + 0.080 X BC + 0.062 X CC − YCD − YCE = 0
0.060 X AD + 0.080 X BD + 0.062 X CD − Y DD − Y DE = 0
0.060 X AE + 0.080 X BE + 0.062 X CE − Y ED − Y EE = 0
X ij ≥ 0 ∀i , j
Y jk ≥ 0 ∀j , k
W j ∈ {0, 1} ∀j
# MODELO EN AMPL CORRESPONDIENTE AL PROBLEMA DE LA BAUXITA
# CONJUNTOS PRINCIPALES
set MINAS; # Conjunto de minas de bauxita indexado por i

set PLALU; # Conjunto de plantas de alúmina indexado por j
set PLESM; # Conjunto de plantas de esmaltado indexado por k
# PARÁMETROS
param capal_es{k in PLESM} >= 0;

# Capacidad de procesamiento de alúmina en la planta de esmaltado k
# (Ton de alúmina/año)
param capb_al{j in PLALU} >= 0;

# Capacidad de procesamiento de bauxita en la planta de alúmina j
# (Ton de bauxita/año)
param capbaux{i in MINAS} >= 0;

# Capacidad de explotación de bauxita de la mina i
param cexp{i in MINAS} >= 0;

# Costo de explotación de la mina i
# ($/Ton de bauxita)
param cfijo{j in PLALU} >= 0;

# Costo fijo de la planta de alúmina j
# ($/año)
param cpal{j in PLALU} >= 0;

# Costo de producción de alúmina en la planta de alúmina j
# ($/Ton de alúmina)
param cpes{k in PLESM} >= 0;

# Costo de procesamiento de la alúmina para producir aluminio
# terminado en la planta de esmaltado k
param ctran_al{j in PLALU, k in PLESM} >= 0;

# Costo de transporte de alúmina desde la planta de alúmina j hacia
# la planta de esmaltado k
param ctran_b{i in MINAS, j in PLALU} >= 0;

# Costo de transporte de bauxita desde la mina de bauxita i hacia
# la planta de alúmina j
# ($/Ton de bauxita)
param demanda{k in PLESM} >= 0;

# Demanda de aluminio terminado en la planta de esmaltado k
# (Ton de aluminio terminado/año
param rendal{i in MINAS} >= 0;

# Rendimiento de alúmina de la bauxita extraída de la mina i
# (Ton de alúmina/Ton de bauxita)
param rendim >= 0;

# Rendimiento de alúmina para producir aluminio terminado
# (Ton de aluminio terminado/Ton de alúmina)
# VARIABLES DE DECISIÓN
var x{i in MINAS, j in PLALU} >= 0;

# Ton de bauxita/año a explotar en la mina i
# y a transportar a la planta de alúmina j
var y{j in PLALU, k in PLESM} >= 0;

# Ton de alúmina/año a producir en la planta de alúmina j
# y a transportar a la planta de esmaltado k
# (Ton de alúmina/año)
var w{j in PLALU} binary;

# Variable binaria igual a 1 si la planta de alúmina j se abre,
# e igual a 0 de lo contrario
# FUNCIÓN OBJETIVO
minimize costo_total: # ($/año)
sum{i in MINAS, j in PLALU} (cexp[i]*x[i,j])

# Costo anual de explotación de bauxita
+ sum{j in PLALU, k in PLESM} (cpal[j]*y[j,k])

# Costo anual de producción de alúmina
+ sum{j in PLALU, k in PLESM} (cpes[k]*y[j,k])

# Costo anual de procesamiento de alúmina en las plantas de esmaltado
+ sum{i in MINAS, j in PLALU} (ctran_b[i,j]*x[i,j])

# Costo anual de transporte de bauxita desde las minas hacia
# las plantas de alúmina
+ sum{j in PLALU, k in PLESM } (ctran_al[j,k]*y[j,k])

# Costo anual de transporte de alúmina desde las plantas de alúmina
# hacia las plantas de esmaltado
+ sum{j in PLALU} (cfijo[j]*w[j]);

# Costo anual fijo de las plantas de alúmina
# RESTRICCIONES
# Por capacidad anual de explotación de bauxita en cada mina

# (Ton de bauxita/año):
subject to cap_exp{i in MINAS}:

sum{j in PLALU} (x[i,j]) <= capbaux[i];
# Por capacidad anual de procesamiento de bauxita

# en cada planta de alúmina
subject to cap_prodal{j in PLALU}:

sum{i in MINAS} (x[i,j]) <= capb_al[j]*w[j];
# Por demanda (ventas) de aluminio terminado

# en cada planta de esmaltado
# (Ton de aluminio terminado/año):
subject to demand_es{k in PLESM}:

sum{j in PLALU} (rendim*y[j,k]) = demanda[k];
# Por balance de masa en cada planta de alúmina
subject to balance{j in PLALU}:

sum{i in MINAS} (rendal[i]*x[i,j]) = sum{k in PLESM} (y[j,k]);
# Restricciones de configuración para análisis de sensibilidad:
# subject to pl_abierta_b:
# w["B"] = 1;
# subject to pl_abierta_c:
# w["C"] = 1;
# subject to pl_abierta_d:
# w["D"] = 1;
# subject to pl_abierta_e:
# w["E"] = 1;
# CONJUNTO DE DATOS EN AMPL CORRESPONDIENTE AL PROBLEMA DE LA BAUXITA
# CONJUNTOS PRINCIPALES
set MINAS:= A B C;
set PLALU:= B C D E;
set PLESM:= D E;
# PARÁMETROS
# Capacidad de procesamiento de alúmina en la planta de esmaltado k

# (Ton de alúmina/año):
param capal_es:=
D 4000
E 7000;
# Capacidad de procesamiento de bauxita en la planta de alúmina j

param capb_al:=
B 40000
C 20000
D 30000
E 80000;
# Capacidad de explotación de bauxita de la mina i

param capbaux:=
A 36000
B 52000
C 28000;
# Costo de explotación de la mina i

# ($/Ton de bauxita):
param cexp:=
A 420
B 360
C 540;
# Costo fijo de la planta de alúmina j

# ($/año):
param cfijo:=
B 3000000
C 2500000
D 4800000
E 6000000;
# Costo de producción de alúmina en la planta de alúmina j

# ($/Ton de alúmina).
param cpal:=
B 330
C 320
D 380
E 240;
# Costo de procesamiento de la alúmina para producir aluminio

# terminado en la planta de esmaltado k
# ($/Ton de alúmina):
param cpes:=
D 8500
E 5200;
# Costo de transporte de alúmina desde la planta de alúmina j hacia

# la planta de esmaltado k
# ($/Ton de alúmina):
param ctran_al: D E :=
B 220 1510
C 620 940
D 0 1615
E 1465 0;
# Costo de transporte de bauxita desde la mina de bauxita i hacia

# la planta de alúmina j
# ($/Ton de bauxita):
param ctran_b: B C D E :=
A 400 2010 510 1920

B 10 630 220 1510
C 1630 10 620 940;
# Demanda de aluminio terminado en la planta de esmaltado k

# (Ton de aluminio terminado/año):
param demanda:=
D 1000
E 1200;
# Rendimiento de alúmina de la bauxita extraída de la mina i

# (Ton de alúmina/Ton de bauxita):
param rendal:=
A 0.060
B 0.080
C 0.062;
# Rendimiento de alúmina para producir aluminio terminado

# (Ton de aluminio terminado/Ton de alúmina):
param rendim:= 0.4;
# COMANDOS EN AMPL CORRESPONDIENTES AL PROBLEMA DE LA BAUXITA
# COMANDOS DE INICIALIZACIÓN DE CONDICIONES:
option show_stats 1;
option solution_precision 0;
option omit_zero_rows 1;
option omit_zero_cols 1;
option display_precision 6;
option display_round 1;
option display_width 50;
# COMANDO DE SOLUCIÓN:
solve;
# COMANDOS DE IMPRESIÓN DE RESULTADOS:
printf "\n\n*************************************\n";
printf "RESULTADOS DEL PROBLEMA DE LA BAUXITA\n";
printf "*************************************\n\n";
printf "\nCOSTO TOTAL = \t%9.1f", costo_total;
printf "\n\nCONFIGURACION DEL SISTEMA (PLANTAS DE ALÚMINA ABIERTAS) =\n\n";

display w;
printf "\nFLUJO DE BAUXITA DESDE MINAS HACIA PLANTAS DE ALÚMINA =\n\n";

display x;
printf "\nFLUJO DE ALÚMINA DESDE PLANTAS DE ALÚMINA HACIA PLANTAS DE ESMALTADO

=\n\n";
display y;
SOLUCIÓN ÓPTIMA DEL PROBLEMA DE LA CADENA DE

ABASTECIMIENTO DE BAUXITA
B
40000
1666.67 1760 1440

A
A T
C D 1000 l e
u r
B 1240 m m
12000
i i
1060 1200 n n
D E i a
20000 o d
C o
E
Minas de Plantas de Plantas de

Bauxita Alúmina Esmaltado
SOLUCIÓN ÓPTIMA DEL PROBLEMA DADA POR QSB:
|----------------------- Solution Summary for Bauxita ------------------------|

| 06-08-2001 08:36:58 Page: 1 of 1 |
|-----------------------------------------------------------------------------|
| | | Objective | | | Objective |
| Variable | Solution |Coefficient | Variable | Solution |Coefficient |
|------------+------------+------------+------------+------------+------------|
| XAB | 0 | 820 | YBD | 1440 | 9050 |
| XAC | 0 | 2430 | YBE | 1760 | 7040 |
| XAD | 1666.667 | 930 | YCD | 0 | 9440 |
| XAE | 0 | 2340 | YCE | 1240 | 6460 |
| XBB | 40000 | 370 | YDD | 1060 | 8880 |
| XBC | 0 | 990 | YDE | 0 | 7195 |
| XBD | 12000 | 580 | YED | 0 | 10205 |
| XBE | 0 | 1870 | YEE | 0 | 5440 |
| XCB | 0 | 2170 | WB | 1 | 3000000 |
| XCC | 20000 | 550 | WC | 1 | 2500000 |
| XCD | 0 | 1160 | WD | 1 | 4800000 |
| XCE | 0 | 1480 | WE | 0 | 6000000 |
|-----------------------------------------------------------------------------|
| Minimized OBJ = 87455600 Iteration = 3 Elapsed CPU seconds = .111328 |
| Branch selection: Newest problem Integer tolerance = .01 Max. #node = 2 |
|-----------------------------------------------------------------------------|
SOLUCIÓN ÓPTIMA DEL PROBLEMA DADA POR AMPL/CPLEX:
OBJECTIVES:
costo_total = 87,455,600
VARIABLES:
w [*] :=
B 1
C 1
D 1
E 0
;
x :=
A B 0
A C 0
A D 1666.67
A E 0
B B 40000
B C 0
B D 12000
B E 0
C B 0
C C 20000
C D 0
C E 0
;
y :=
B D 1440
B E 1760
C D 0
C E 1240
D D 1060
D E 0
E D 0
E E 0
;
CONSTRAINTS (Dual Values):

balance [*] :=
B 15330
C 15910
D 15500
E 16930
;
cap_exp [*] :=
A 0
B -660
C 0
;
cap_prodal [*] :=
B -196.4
C -436.42
D 0
E 0
;
demand_es [*] :=
D 60950
E 55925
;
ALGUNOS ANÁLISIS DE LA SOLUCIÓN ÓPTIMA:
1. CAPACIDAD ANUAL DE LAS MINAS:
Mina A: Sólo se utilizan 1,666.67 ton/año de las 36,000 ton/año disponibles.

Mina B: Se utiliza a la máxima capacidad de 52,000 ton/año.
Mina C: Sólo se utilizan 20,000 ton/año de las 28,000 ton/año disponibles.
2. CAPACIDAD ANUAL DE PROCESAMIENTO DE BAUXITA EN LAS PLANTAS DE ALÚMINA:
Planta B: Se utiliza a la máxima capacidad de 40,000 ton de bauxita/año.

Planta C: Se utiliza a la máxima capacidad de 20,000 ton de bauxita/año.
Planta D: Sólo se utilizan 13,666.67 ton/año de las 30,000 disponibles.
Planta E: No se abre.
3. CAPACIDAD ANUAL DE PROCESAMIENTO DE ALÚMINA EN LAS PLANTAS DE ESMALTADO:
Planta D: Sólo se utilizan 2,500 ton/año de las 4,000 ton/año disponibles.

Planta E: Sólo se utilizan 3,000 ton/año de las 7,000 ton/año disponibles.
4. BALANCE DE MASA EN LAS PLANTAS DE ALÚMINA:
Verificar que éstas se cumplen exactamente.
ALGUNOS ANÁLISIS DE SENSIBILIDAD:
1. Si se obliga a la planta de alúmina E a estar abierta: Se abren todas las

plantas, pero no se produce nada en la planta de alúmina E. Simplemente se
paga su costo fijo y el costo total anual asciende a 93,455,600 $/año.
2. Si sólo se abren las plantas B y C, el problema no tiene ninguna solución

factible.
3. Si sólo se abren las plantas B, C y E, se obtiene una solución óptima con

un costo mínimo de 103,457,000 $/año.
Se sugiere al lector realizar otros análisis de sensibilidad.

Problema Bauxita Completo PDF

Загружено:

Сведения о документе

Оригинальное название

Авторское право

Доступные форматы

Поделиться этим документом

Поделиться или встроить документ

Параметры публикации

Этот документ был вам полезен?

Это неприемлемый материал?

Авторское право:

Доступные форматы

Problema Bauxita Completo PDF

Загружено:

Авторское право:

Доступные форматы

Sistemas de Transporte y Redes de Abastecimiento: Cadena de suministro de la bauxita 1

PROBLEMA DE LA BAUXITA: Ejemplo de una cadena de abastecimiento

Preparado por: Carlos Julio Vidal Holguín, Escuela de Ingeniería Industrial y

Una compañía multinacional de aluminio tiene depósitos de bauxita (materia prima) en

Minas de Costo de Capacidad anual Rendimiento

Conversión de Bauxita en Alúmina:

Costo Producción Capacidad anual Costo fijo anual

Costo Capacidad anual

Costos de transporte en $/ton de Bauxita:

Costos de transporte de la alúmina, en $/ton de alúmina:

Los lingotes de producto terminado no se transportan entre D y E y viceversa. Formule y

MODELO DE OPTIMIZACIÓN PROPUESTO

Minas de Plantas de Plantas de

La figura muestra el esquema de la cadena de abastecimiento planteada. Se definen

Yjk = Ton/año de alúmina a transportar desde la planta de alúmina j hacia la planta

Wj = 1, si la planta de alúmina j se abre; 0, de lo contrario; j = B, C, D, E.

+ Costo anual de producción de alúmina

+ Costo anual de procesamiento de alúmina en las

+ Costo anual de transporte de bauxita desde las minas

+ Costo anual de transporte de alúmina desde las

+ Costo fijo anual de las plantas de alúmina

Costo anual de explotación de bauxita ($/año):

Costo anual de producción de alúmina ($/año):

Costo anual de procesamiento de alúmina en las plantas de esmaltado ($/año):

Planta D : 8500(Y BD + YCD + Y DD + Y ED )

Desde la mina A : 400 X AB + 2010 X AC + 510 X AD + 1920 X AE

Hacia la planta D : 220Y BD + 620YCD + 1465Y ED

Costo fijo anual de plantas de alúmina ($/año):

1) Por capacidad anual de explotación de bauxita en cada mina (Ton de bauxita/año):

2) Por capacidad anual de procesamiento de bauxita en cada planta de alúmina (Ton de

3) Por capacidad anual de procesamiento de alúmina en cada planta de esmaltado (Ton

Planta D : Y BD + YCD + Y DD + Y ED ≤ 4,000

4) Por ventas anuales de aluminio terminado en cada planta de esmaltado (Ton de

Planta D : 0.4(Y BD + YCD + Y DD + Y ED ) = 1,000

Estas restricciones aseguran que la demanda anual proyectada en cada planta de

5) Por balance de masa en cada una de las plantas de alúmina:

Planta B : 0.060 X AB + 0.080 X BB + 0.062 X CB = Y BD + Y BE

6) Por límites en los valores de cada una de las variables:

Estas restricciones, denominadas comúnmente obvias, simplemente expresan la

El modelo matemático para resolver el problema planteado comprende entonces

Los modelos matemáticos de cadenas de abastecimiento reales pueden contener

Minimizar Costo Total Anual (CTA) =

820 X AB + 2430 X AC + 930 X AD + 2340 X AE + 370 X BB + 990 X BC + 580 X BD + 1870 X BE

0.4(Y BD + YCD + Y DD + Y ED ) = 1,000

0.060 X AB + 0.080 X BB + 0.062 X CB − Y BD − Y BE = 0

# MODELO EN AMPL CORRESPONDIENTE AL PROBLEMA DE LA BAUXITA

set MINAS; # Conjunto de minas de bauxita indexado por i

param capal_es{k in PLESM} >= 0;

param capb_al{j in PLALU} >= 0;

param capbaux{i in MINAS} >= 0;

param cexp{i in MINAS} >= 0;

param cfijo{j in PLALU} >= 0;

param cpal{j in PLALU} >= 0;

param cpes{k in PLESM} >= 0;

param ctran_al{j in PLALU, k in PLESM} >= 0;

param ctran_b{i in MINAS, j in PLALU} >= 0;

param demanda{k in PLESM} >= 0;

param rendal{i in MINAS} >= 0;

param rendim >= 0;

var x{i in MINAS, j in PLALU} >= 0;

var y{j in PLALU, k in PLESM} >= 0;

var w{j in PLALU} binary;

minimize costo_total: # ($/año)