/prep7

/title, FINITE ELEMENT MODEL OF CYLINDRAL SHELL WITH FLUID80 (alpha = 0)

c**** parameter
! geometry parameter
H=11.100 ! total height
r0=10.0 !m, mean radius of shell at mid height
alpha=0 ! degree of angle at mid height
t=0.0065 ! shell thickness
! modeling parameter
nax=20 ! number of element in axial direction
nci=12 ! number of element in circumferential direction per quarter
ncit=nci*4 ! total number of element in circumferential direction
pi=3.14159265
degree=(pi/180)*alpha
steep=tan(degree)
rplus=steep*(H/2)
rb=r0+rplus
rt=r0-rplus
rfd=(t/2)/cos(degree)
rfb=rb-rfd
rft=rt-rfd
!properity parameter Aluminium
!shell
ex1=210.0e9 ! Pa, elastic modulus of shell element
dens1=7850! kgf/m^3, density of shell element
nuxy1=0.3 ! poisson's ratio of shell element
!fluid80
dens2=1000 ! kgf/m^3
ex2=2.2e9 ! elastic modulus of water
visco2=1.130e-3 ! viscosity of water
damp2=0.01 !1%
!!
!alpx2 = ???
SONC2=1500 ! m/sec
MU2=0.001 ! 0,1%
!!
c**** model generation
! material properties and element definition
! shell material properity
et,1,shell181 ! SHELL181
r,1,t
mp,ex,1,ex1
mp,dens,1,dens1
mp,nuxy,1,nuxy1
! Fluid material properity
et,2,fluid80
mp,ex,2,ex2
mp,dens,2,dens2
mp,visc,2,visco2

acel,,,9.80665
!shell model generation
k,
csys,1
k,2,rb
k,3,rt,,H
lstr,2,3
k,4,,,2*H
arotat,1,,,,,,1,4,360
!shell model mesh generation (ncit*nax)
lsel,s,line,,1,4
lesize,all,,,nax ! height/nax
lsel,s,line,,5,12
lesize,all,,,nci ! circumferential direction / nci per quatrter
type,1
mat,1
real,1
eshape,2
amesh,all
!fluid model generation
type,2
mat,2
real,2
eshape,2
cone,rfb,rft,H,,0,360,
c****volume divide and mesh
! volume divide with working plane to 4
kwplan,,1,2,4
vsbw,1
kwplan,,1,14,4
vsel,all
vsbw,all
numcomp,volume
vsel,all
aslv
lsla
lsel,r,loc,z,0
lesize,all,,,nci
lsla
lsel,r,loc,z,H
lesize,all,,,nci
lsla
lsel,u,loc,z,0
lsel,u,loc,z,H
lesize,all,,,nax
vmesh,all
esel,all
nsel,all
c*** BOUNDARY CONDITION
csys,1
c***botom and top nodes of shell (clamped)
esel,s,type,,1
nsle
nsel,r,loc,z,0
nrotat,all
d,all,all,0 ! clamped condition
esel,s,type,,1
nsle
nsel,r,loc,z,H
nrotat,all
d,all,all,0 !clamped condition
c***botom and top nodes of fluid
esel,s,type,,2
nsle
nsel,r,loc,z,0
nrotat,all
d,all,uz,0 ! no axial movement
esel,s,type,,2
nsle
nsel,r,loc,z,H
nrotat,all
d,all,uz,0 ! no axial movement
c**** COUPLED DOF
m1=1
n1=0
*do,i,0,360-(360/ncit),360/ncit
*do,j,0,nax,1
csys,1
hz=(H/nax)*j
rxout=-steep*hz+rb
rxin=-steep*hz+rfb
nsel,s,loc,z,hz
nsel,r,loc,x,rxin,rxout
nsel,r,loc,y,i
c1=m1+n1
n1=n1+1
local,11,1,0,0,hz,i,,-alpha
csys,11
nrotat,all
cp,c1,ux,all
*enddo
m1=100
*enddo
c***
nsel,all
esel,all
!/show,sh4,mod,1 ! model plot
!/SHOW,PNG
!/GFILE,600,
!/RGB,INDEX,100,100,100, 0
!/RGB,INDEX, 80, 80, 80,13
!/RGB,INDEX, 60, 60, 60,14
!/RGB,INDEX, 0, 0, 0,15
!/inp,v4n
!lplo
!aplo
!vplo
!esel,,type,,1
!nsle
!eplot
!esel,,type,,2
!nsle
!eplo
!alls
!save
!finish