Вы находитесь на странице: 1из 24

Методика оперативного проведения и управляемые

25th July 2013


блокировки
Введение.

Несмотря на то, что у меня уже есть статья посвященная механизму оперативного проведения, очень часто,
нет не так, очень-очень-очень часто спрашивают, что это такое.
Я подумал и решил написать ну очень-очень-очень подробную статью про методику оперативного
проведения и управляемые блокировки. А без управляемых блокировок, собственно, методику
использовать бессмысленно.

При написании статьи, демопример я вводил на платформе 8.3.3.641. Всю задачу создавал на пустой базе.

Постановка задачи.

Необходимо автоматизировать 2 операции: покупка, продажа товаров. При продаже товаров необходимо
контролировать наличие товаров в остатках предприятия и рассчитывать себестоимость списания товаров
по методу FIFO.

Начнем...

Структура метаданных:
Справочник: Товары
Документы: Приходная и Расходная с табличными частями "Список товаров" (товар, количество, сумма).
Регистры: ОстаткиТоваров, в регистре одно измерение: Товар, и один ресурс: Количество.
Назначение регистра - быстрое принятие решения, можно ли проводить документ.
СтоимостьТоваров, в регистре два измерения: Товар, Партия, и два ресурса: Количество, Стоимость.
Назначение регистра: хранение информации о стоимости остатков товаров в разрезе партий.

Описывать проведение документа "Приходная" не буду, там все очевидно, все можно конструктором
сделать.

В расходной опишем проведение по регистру ОстаткиТоваров...

Методика оперативного проведения.

Под термином "Методика оперативного проведения" я понимаю следующее: при проведении документа,
вместо того, чтобы, сформировать запрос и понять хватает ли товаров или нет, мы сначала сформируем
движения, а затем уже проверим, не ушли ли мы в минус? Подробнее с плюсами и минусами этой
технологии можно познакомиться в моей прошлой статье [http://1c.chistov.pro/2010/06/1-82.html] .

Опишем формирование движений в документе "Расходная":

Процедура ОбработкаПроведения(Отказ, Режим)

//1
Движения.ОстаткиТоваров.Записывать = Истина;

//2
Движения.ОстаткиТоваров.Очистить();
Для каждого Стр Из СписокТоваров Цикл
Движение = Движения.ОстаткиТоваров.ДобавитьРасход();
Движение.Период = Дата;
Движение.Товар = Стр.Товар;
Движение.Количество = Стр.Количество;
КонецЦикла;

//3
КонецПроцедуры

Прокомментируем текст модуля:


1. Устанавливаем маркер необходимости записи движений. Это необходимо делать в том случае, если у
документа установлено свойство "Записывать выбранные".

[//3.bp.blogspot.com/-
imqpRsu2Kg4/Ue2XulurgzI/AAAAAAAAX50/SbPTJM5h8SY/s1600/23-07-2013+0-23-52.png]

Что дает нам это свойство?


Интересную фишку, раньше мы могли принудительно записать движения документа (наборы данных), но
при окончании транзакции проведения наборы данных записывались еще раз. Теперь мы вольны в выборе,
что и когда нужно записывать. Маркер записи автоматически снимается при записи набора, тем самым,
при окончании транзакции проведения, набор записей еще раз записываться не будет. К чему это
приведет? Правильно, к уменьшению блокировок таблиц и к сокращению времени транзакций при
проведении.

2. Очищаем движения. Зачем? Все дело в еще одном новом свойстве документов "Удалять движения".

[//4.bp.blogspot.com/-
gYI_EYwPAQA/Ue2XuohCbkI/AAAAAAAAX6A/VKSlqRzRIPc/s1600/23-07-2013+0-34-16.png]
При установленном свойстве "Удалять автоматически" в самом начале транзакции проведения система
автоматически записывает пустые наборы записей в регистры, тем самым очищая старые движения. Это
физически происходит, запись, со всеми вытекающими транзакциями и блокировками.
Для облегчения нагрузки на таблицы баз данных теперь есть возможность не очищать автоматом старые
движения...
И тут обычно я слышу: "Так и всегда можно было "Не очищать автоматически"! Ага, можно было, но в
каждом документе приходилось описывать очистку каждого набора записей при отмене проведения...
Удобно...
Короче, 1С пошла на поводу у здравого смысла и сделала новое свойство "Удалять автоматически при
отмене проведения", Это гарантирует нам, что все движения документа будут очищены в том случае если у
документа отработает событие "ОтменаПроведения".
Теперь вопрос, а зачем мы в модуле написали "Очистить()", тут все дело в том, что теперь у нас движения
автоматом не очищаются... НО! При работе с управляемыми формами копия объекта БД может не
загрузить старые движения, к примеру, зависит это и от свойства данных формы "Использовать всегда".

[//4.bp.blogspot.com/-
WeFAG6eA5tk/Ue2bYT38rjI/AAAAAAAAX6M/SiXVGIeNsQ4/s1600/23-07-2013+0-50-00.png]
К примеру, в зависимости от этого свойства, движения документа будут прочитаны (если галка стоит) при
открытии формы или нет. А если даже галка не установлена, и в форме отображаются движения, то
движения будут прочитаны при открытии формы.
В обычных формах движения будут однозначно прочитаны при открытии формы.
А если движения прочитаны, то наборы записей в свойстве документа "Движения" не пустые, и добавление
при проведении новых движений, как правило приводит к дублям движений.
Так вот, чтобы не зависеть от обстоятельств, мы на всякий случай удаляем то, что возможно может
находиться в коллекции движений по регистру ОстаткиТоваров. Обращаю внимание, что запись данных в
базу тут не производится, просто в памяти очищается набор записей.
Кстати, если свойство конфигурации "Основной режим запуска" будет установлено в значение "Обычное
приложение", то такую строку "Движения.ИмяРегистра.Очистить()" будет писать и сам конструктор
формирования движений.
[//4.bp.blogspot.com/-
R6cz4NiSlSA/Ue2c5WP_lWI/AAAAAAAAX6c/QQyQFWix8jI/s1600/23-07-2013+0-56-58.png]
3. Итак, движения сформировали, самое время их записать. Тут есть два варианта.
либо Движения.Записать(); либо Движения.ОстаткиТоваров.Записать(); В чем разница и что выбрать?
Начнем с последнего: Движения.ОстаткиТоваров.Записать(); Этот способ безусловно запишет данные в регистр
накопления. Но при этом флаг "Записывать" у набора записей снят не будет. Но это ерунда, главное тут то,
что при большом количестве наборов записей у документа нам придется самостоятельно контролировать
что в каком порядке в базу пишется, это может (да что там "может", точно скажется) негативно сказаться
на проблеме взаимных блокировок (DeadLock), когда одна транзакция заблокирует таблицу А и будет
ждать освобождения таблицы Б, а другая транзакция будет вести себя строго наоборот.
теперь посмотрим как работает метод Движения.Записать(); Метод записывает только те движения документа
у которых установлен флаг "Записывать", при этом флаг в итоге снимается, что не приводит к повторной
записи движений по окончании транзакции проведения. И главное, Движения.Записать(); всегда записывают
движения в том порядке в котором таблицы указаны в дереве метаданных, что на порядок уменьшает
шансы взаимных блокировок, ведь все транзакции в одинаковом порядке блокируют таблицы.
Теперь надеюсь очевидно, выбираем метод Движения.Записать();

Запишем движения и проверим остатки в регистре.

//3
Движения.Записать();

Запрос = Новый Запрос;

//4
Запрос.МенеджерВременныхТаблиц = Новый МенеджерВременныхТаблиц;
Запрос.Текст = "ВЫБРАТЬ
| Док.Товар КАК Товар,
| СУММА(Док.Количество) КАК Количество
|ПОМЕСТИТЬ ДокТЧ
|ИЗ
| Документ.Расходная.СписокТоваров КАК Док
|ГДЕ
| Док.Ссылка = &Ссылка
|
|СГРУППИРОВАТЬ ПО
| Док.Товар
|
|ИНДЕКСИРОВАТЬ ПО
| Товар
|;
|
|/////////////////////////////////////////////////////////////////////////
///////
|ВЫБРАТЬ
| Остатки.Товар.Представление КАК ТоварПредставление,
| Остатки.КоличествоОстаток
|ИЗ
| РегистрНакопления.ОстаткиТоваров.Остатки(
| &ТочкаИтогов,
| Товар В
| (ВЫБРАТЬ
| ДокТЧ.Товар
| ИЗ
| ДокТЧ КАК ДокТЧ)) КАК Остатки
|ГДЕ
| Остатки.КоличествоОстаток < 0
|;
|
|/////////////////////////////////////////////////////////////////////////
///////
|ВЫБРАТЬ
| ДокТЧ.Товар
|ИЗ
| ДокТЧ КАК ДокТЧ";
Запрос.УстановитьПараметр("Ссылка", Ссылка);

//5

Запрос.УстановитьПараметр("ТочкаИтогов", Новый Граница(МоментВремени(), ВидГраницы.Включа


я));

ПакетРезультатов = Запрос.ВыполнитьПакет();
РезультатЗапроса = ПакетРезультатов[1];

Если НЕ РезультатЗапроса.Пустой() Тогда


//6
Отказ = Истина;

Выборка = РезультатЗапроса.Выбрать();
Пока Выборка.Следующий() Цикл
Сообщение = Новый СообщениеПользователю;
Сообщение.Текст = "Мало товара " + Выборка.ТоварПредставление + " нужно еще " + (-Выбо
рка.КоличествоОстаток);
Сообщение.Сообщить();
КонецЦикла;
КонецЕсли;

Если Отказ Тогда


Возврат;
КонецЕсли;

Комментарии к модулю:
4. Привязываем к запросу менеджер временных таблиц. Это позволит использовать временные таблицы
позже для проведения по регистру с партиями товаров.
В запросе выбираем из табличной части документа товары и количество, группируем все и индексируем по
полю Товар. Это, в общем случае, благоприятно скажется на быстродействии запроса.
5. ТочкаИтогов, здесь мы используем объект Граница. Так как передав в запрос просто "МоментВремени()"
мы получили бы остатки на начало проведения документа, то есть не включили бы в расчет итогов только
что сформированные движения документа. А нам нужно понять, что произошло с итогами после
проведения документа.

В целом все.

Мы используем новую методику проведения документа. Сначала записали данные в регистр, а потом через
кэш транзакции смотрим не ушли ли мы в минус. Если ушли - транзакцию отказываем.

Но это далеко не все. Назревает вопрос о "грязном чтении".

Грязное чтение.

Что это такое?


Я не буду вдаваться в теорию (в отличии от вас, вам я советую в теорию копнуть, лишним не будет), поясню
на примере:
Проводим две расходных. И в одной и в другой продаем 5 ложек. А в остатках всего 6. Так получилось, что
продавать ложки мы умудрились в один и тот-же момент времени. Что произойдет?
Первая накладная сформирует движения и начнет читать запрос по остаткам через кэш собственной
транзакции, что, собственно, будет делать и вторая накладная. Но ложек-то всего 6, а в сумме две
накладные продадут 10... Потому-что не знают о том, что данные в таблицах уже не актуальны...
Что делать?
Надо заблокировать данные от параллельного чтения.
В нашем примере это сделать очень просто. У набора записей есть свойство "БлокироватьДляИзменения".
Это, как и свойство "Записывать", лишь маркер указывающий, что необходимо установить блокировку на
те записи, которые были сформированы в наборе записей.
Когда устанавливать свойство "БлокироватьДляИзменения"? Не важно, главное до самой записи данных.
Когда произойдет блокировка записей? В момент записи данных.
Что означает эта блокировка?
Никто параллельно с нами читать данные из регистра по тем товарам, движения по которым были
сформированы, не сможет.
Когда блокировка будет снята?
При окончании транзакции в которой она началась, в нашем примере, при завершении проведения
документа.

Установим блокировку:

//2
Движения.ОстаткиТоваров.Очистить();

Для каждого Стр Из СписокТоваров Цикл


Движение = Движения.ОстаткиТоваров.ДобавитьРасход();
Движение.Период = Дата;
Движение.Товар = Стр.Товар;
Движение.Количество = Стр.Количество;
КонецЦикла;

//7
Движения.ОстаткиТоваров.БлокироватьДляИзменения = Истина;

//3
Движения.Записать();

Казалось бы все, а давайте проверим какие свойства нужно установить у объектов, для того, чтобы такая
блокировка не просто работала, а еще и блокировала только те записи по которым были сформированы
движения...

А. Свойство конфигурации "Режим управления блокировкой данных в транзакции" - если, "Управляемый",


то все хорошо.
Если "Автоматический", то системе глубоко фиолетово на то что мы с вами написали. В нашем частном
случае, блокировка в режиме "Автоматический" не будет установлена.
Если "и то и другое" то важно проверить настройки объектов. Помните, что вид транзакции наследуется
всеми вложенными транзакциями. То есть если документ записывается в автоматической транзакции, а
движения делает по регистрам с управляемой... То система немного расстроится и вывалится с ошибкой.

Б. Так как блокируем мы не весь регистр, за что нам отдельное спасибо, а только те данные по которым
мы сформировали движения, за что спасибо ребятам из 1С, то важно установить свойство регистра
"Разрешить разделение итогов".

[//1.bp.blogspot.com/-
rDnpP0bgMxI/Ue2soy8AuhI/AAAAAAAAX6s/pOIp87cj1-w/s1600/23-07-2013+2-04-17.png]
Если разделение итогов не будет включено и в режиме пользователя, то в большей части случаев
блокировка будет наложена на весь регистр с его таблицами.

Вот теперь точно с регистром "ОстаткиТоваров" все. Займемся себестоимостью.

Партионное списание.

При списании партий из регистра "СтоимостьТоваров" использовать методику оперативного проведения


мы не можем. Почему? А для того, чтобы списать партии нужно узнать какие конкретно, то есть нам нужно
сначала прочитать данные из регистра, а потом уже формировать движения.

Если Отказ Тогда


Возврат;
КонецЕсли;

//7
Запрос.Текст = "ВЫБРАТЬ
| ДокТЧ.Товар КАК Товар,
| ДокТЧ.Количество КАК Количество,
| СтоимостьТоваров.Партия,
| СтоимостьТоваров.КоличествоОстаток,
| СтоимостьТоваров.СтоимостьОстаток
|ИЗ
| ДокТЧ КАК ДокТЧ
| ЛЕВОЕ СОЕДИНЕНИЕ РегистрНакопления.СтоимостьТоваров.Остатки(
| &ТочкаИтоговДляСебестоимости,
| Товар В
| (ВЫБРАТЬ
| ДокТЧ.Товар
| ИЗ
| ДокТЧ КАК ДокТЧ)) КАК СтоимостьТоваров
| ПО ДокТЧ.Товар = СтоимостьТоваров.Товар
|
|УПОРЯДОЧИТЬ ПО
| СтоимостьТоваров.Партия.МоментВремени
|ИТОГИ
| МИНИМУМ(Количество)
|ПО
| Товар";

//8
Запрос.УстановитьПараметр("ТочкаИтоговДляСебестоимости", МоментВремени());

//9
Движения.СтоимостьТоваров.Очистить();

//10
РезультатЗапроса = Запрос.Выполнить();
ВыборкаТовар = РезультатЗапроса.Выбрать(ОбходРезультатаЗапроса.ПоГруппировкам);

Пока ВыборкаТовар.Следующий() Цикл


ОсталосьСписать = ВыборкаТовар.Количество;

ВыборкаПартия = ВыборкаТовар.Выбрать();
Пока ВыборкаПартия.Следующий() И ОсталосьСписать <> 0 Цикл

Списать = МИН(ОсталосьСписать, ВыборкаПартия.КоличествоОстаток);

Движение = Движения.СтоимостьТоваров.ДобавитьРасход();
Движение.Период = Дата;
Движение.Товар = ВыборкаПартия.Товар;
Движение.Партия = ВыборкаПартия.Партия;
Движение.Количество = Списать;
Движение.Стоимость = Списать / ВыборкаПартия.КоличествоОстаток * ВыборкаПартия.Стоимос
тьОстаток;

ОсталосьСписать = ОсталосьСписать - Списать;

КонецЦикла;

КонецЦикла;

//11
Движения.СтоимостьТоваров.Записывать = Истина;

Комментарии к модулю:
7. После проверки будем ли мы проводить документ, описываем новый текст запроса. Новый объект
запрос создавать нет смысла, будем использовать уже существующий, кроме всего к нему уже подключен
менеджер временных таблиц в котором содержится проиндексированная таблица ДокТЧ.
8. Устанавливаем МоментВремени() как точку расчета итогов таблицы остатков. Как было описано выше,
по умолчанию эта точка (то бишь старые движения, которые мог бы сформировать этот документ) в расчет
итогов не попадут. Но тут есть одна хитрость к которой мы вернемся немного позже.
9. На всякий случай очистим движения документа, вдруг они были прочитаны.
10. Опишем списание по партиям.
11. Установим маркер необходимости записи данных по регистру "СтоимостьТоваров".
Когда транзакция проведения будет завершена система самостоятельно запишет движения в базу.

Почти все, остались блокировки.

Управляемые блокировки.

По регистру "СтоимостьТоваров" воспользоваться флагом "БлокироватьДляИзменения" нам не удастся.


Почему? Да потому-что блокировка с этим флагом происходит в момент записи данных набора записей, а
нам блокировку нужно установить еще перед запросом, дабы не допустить параллельного чтения данных.

По этому, для установки блокировки будем использовать объект "БлокировкаДанных".


Объект "БлокировкаДанных" представляет таблицу, каждая строка которой описывает что и где нужно
заблокировать.

Если Отказ Тогда


Возврат;
КонецЕсли;

//12
Блокировка = Новый БлокировкаДанных;
//13
ЭлементБлокировки = Блокировка.Добавить("РегистрНакопления.СтоимостьТоваров");
ЭлементБлокировки.Режим = РежимБлокировкиДанных.Исключительный;
//14
ЭлементБлокировки.ИсточникДанных = ПакетРезультатов[2];
//15
ЭлементБлокировки.ИспользоватьИзИсточникаДанных("Товар", "Товар");
Блокировка.Заблокировать();

//7
Запрос.Текст = "ВЫБРАТЬ

Перед нашим вторым текстом запроса опишем блокировку.


12. Создаем объект.
13. Добавляем в объект новую строку с описанием блокируемой таблицы.
14. Для того чтобы не блокировать весь регистр, установим фильтр по товарам, данные о том по каким
товарам необходимо заблокировать таблицы хранятся у нас в результате первого запроса, из пакета
результатов достаем последний. Можно было и саму табличную часть документа привязать к источнику
данных, но тогда система еще раз строила бы запрос к табличной части документа, а так мы все данные
уже получили, сгруппировали.
15. Так как в результате запроса поле содержащее список с товарами может называться не так как поле в
регистре, описываем соответствие.

Установили блокировку. Теперь параллельно с нами никто не прочитает остатки по указанным товарам из
регистра "СтоимостьТоваров". Обращаю внимание, так как мы не знаем заранее какие партии будут
выбраны запросом, то фильтр по ним установить мы не можем и блокируем все партии. Чем меньше
фильтров описано, тем больше данных блокируется.

И вот тут казалось бы все, а нет.

Проблема оперативного проведения.

Если сейчас попробовать провести документ оперативно 2 раза, указывая последние товары в регистре, то
система вылетит с ошибкой. Почему?
При оперативном проведении, несмотря на то, что, мы указали в параметре второго запроса
"МоментВремени()" и он вроде бы не должен включить старые движения документа, система рассчитает
остатки на оперативную отметку времени, то есть старые движения будут включены в расчет итогов. Да,
да... Вот такая "фишка".
Что делать? Отследим оперативное проведение и очистим старые движения.
Перед описание второго запроса вставим такой код:

//16
Если Режим = РежимПроведенияДокумента.Оперативный Тогда
Движения.СтоимостьТоваров.Очистить();
//17
Движения.СтоимостьТоваров.БлокироватьДляИзменения = Истина;
Движения.СтоимостьТоваров.Записать();
КонецЕсли;

//7
Запрос.Текст = "ВЫБРАТЬ

16. Проверяем оперативно ли проводится документ.


17. Устанавливаем свойство "БлокироватьДляИзменения". Это позволит заблокировать от чтения те
данные которые сейчас будут удалены из регистра, вдруг транзакция будет отменена, не хотим чтобы кто-
либо вместе с нами работал с этими данными.
Подобное действие не помешает и при смене даты или времени документа, а не только при оперативном
проведении.

Вот теперь все. Полный текст модуля документа "Расходная":

Процедура ОбработкаПроведения(Отказ, Режим)

//1
Движения.ОстаткиТоваров.Записывать = Истина;

//2
Движения.ОстаткиТоваров.Очистить();

Для каждого Стр Из СписокТоваров Цикл


Движение = Движения.ОстаткиТоваров.ДобавитьРасход();
Движение.Период = Дата;
Движение.Товар = Стр.Товар;
Движение.Количество = Стр.Количество;
КонецЦикла;

//7
Движения.ОстаткиТоваров.БлокироватьДляИзменения = Истина;

//3
Движения.Записать();

Запрос = Новый Запрос;

//4
Запрос.МенеджерВременныхТаблиц = Новый МенеджерВременныхТаблиц;
Запрос.Текст = "ВЫБРАТЬ
| Док.Товар КАК Товар,
| СУММА(Док.Количество) КАК Количество
|ПОМЕСТИТЬ ДокТЧ
|ИЗ
| Документ.Расходная.СписокТоваров КАК Док
|ГДЕ
| Док.Ссылка = &Ссылка
|
|СГРУППИРОВАТЬ ПО
| Док.Товар
|
|ИНДЕКСИРОВАТЬ ПО
| Товар
|;
|
|////////////////////////////////////////////////////////////////////////
////////
|ВЫБРАТЬ
| Остатки.Товар.Представление КАК ТоварПредставление,
| Остатки.КоличествоОстаток
|ИЗ
| РегистрНакопления.ОстаткиТоваров.Остатки(
| &ТочкаИтогов,
| Товар В
| (ВЫБРАТЬ
| ДокТЧ.Товар
| ИЗ
| ДокТЧ КАК ДокТЧ)) КАК Остатки
|ГДЕ
| Остатки.КоличествоОстаток < 0
|;
|
|////////////////////////////////////////////////////////////////////////
////////
|ВЫБРАТЬ
| ДокТЧ.Товар
|ИЗ
| ДокТЧ КАК ДокТЧ";
Запрос.УстановитьПараметр("Ссылка", Ссылка);

//5
Запрос.УстановитьПараметр("ТочкаИтогов", Новый Граница(МоментВремени(), ВидГраницы.Включ
ая));

ПакетРезультатов = Запрос.ВыполнитьПакет();
РезультатЗапроса = ПакетРезультатов[1];

Если НЕ РезультатЗапроса.Пустой() Тогда


//6
Отказ = Истина;

Выборка = РезультатЗапроса.Выбрать();
Пока Выборка.Следующий() Цикл
Сообщение = Новый СообщениеПользователю;
Сообщение.Текст = "Мало товара " + Выборка.ТоварПредставление + " нужно еще " + (-Выбо
рка.КоличествоОстаток);
Сообщение.Сообщить();
КонецЦикла;
КонецЕсли;

Если Отказ Тогда


Возврат;
КонецЕсли;

//12
Блокировка = Новый БлокировкаДанных;
//13
ЭлементБлокировки = Блокировка.Добавить("РегистрНакопления.СтоимостьТоваров");
ЭлементБлокировки.Режим = РежимБлокировкиДанных.Исключительный;
//14
ЭлементБлокировки.ИсточникДанных = ПакетРезультатов[2] ;
//15
ЭлементБлокировки.ИспользоватьИзИсточникаДанных("Товар", "Товар");
Блокировка.Заблокировать();

//16
Если Режим = РежимПроведенияДокумента.Оперативный Тогда
Движения.СтоимостьТоваров.Очистить();
//17
Движения.СтоимостьТоваров.БлокироватьДляИзменения = Истина;
движения.СтоимостьТоваров.Записать();
КонецЕсли;

//7
Запрос.Текст = "ВЫБРАТЬ
| ДокТЧ.Товар КАК Товар,
| ДокТЧ.Количество КАК Количество,
| СтоимостьТоваров.Партия,
| СтоимостьТоваров.КоличествоОстаток,
| СтоимостьТоваров.СтоимостьОстаток
|ИЗ
| ДокТЧ КАК ДокТЧ
| ЛЕВОЕ СОЕДИНЕНИЕ РегистрНакопления.СтоимостьТоваров.Остатки(
| &ТочкаИтоговДляСебестоимости,
| Товар В
| (ВЫБРАТЬ
| ДокТЧ.Товар
| ИЗ
| ДокТЧ КАК ДокТЧ)) КАК СтоимостьТоваров
| ПО ДокТЧ.Товар = СтоимостьТоваров.Товар
|
|УПОРЯДОЧИТЬ ПО
| СтоимостьТоваров.Партия.МоментВремени
|ИТОГИ
| МИНИМУМ(Количество)
|ПО
| Товар";

//8
Запрос.УстановитьПараметр("ТочкаИтоговДляСебестоимости", МоментВремени());

//9
Движения.СтоимостьТоваров.Очистить();

//10
РезультатЗапроса = Запрос.Выполнить();
ВыборкаТовар = РезультатЗапроса.Выбрать(ОбходРезультатаЗапроса.ПоГруппировкам);

Пока ВыборкаТовар.Следующий() Цикл

ОсталосьСписать = ВыборкаТовар.Количество;

ВыборкаПартия = ВыборкаТовар.Выбрать();
Пока ВыборкаПартия.Следующий() И ОсталосьСписать <> 0 Цикл

Списать = МИН(ОсталосьСписать, ВыборкаПартия.КоличествоОстаток);

Движение = Движения.СтоимостьТоваров.ДобавитьРасход();
Движение.Период = Дата;
Движение.Товар = ВыборкаПартия.Товар;
Движение.Партия = ВыборкаПартия.Партия;
Движение.Количество = Списать;
Движение.Стоимость = Списать / ВыборкаПартия.КоличествоОстаток * ВыборкаПартия.Стоимос
тьОстаток;

КонецЦикла;

КонецЦикла;

//11
Движения.СтоимостьТоваров.Записывать = Истина;
КонецПроцедуры

Надеюсь после этой статьи большая часть вопросов о "новой" методике проведения и о том почему нельзя
повсеместно писать "БлокироватьДляИзменения = Истина" будут закрыты.

Актуальная версия статьи располагается тут [http://1c.chistov.pro/2013/07/blog-post_25.html] .


Контакты автора на сайте chistov.pro [http://chistov.pro/]

Опубликовано 25th July 2013 пользователем Павел Чистов


Ярлыки: методика оперативного проведения, блокировка данных, блокироватьДляИзменения,
управляемые блокировки

71 Просмотреть комментарии

Анонимный 14 августа 2013 г., 11:39


Подскажите, пожалуйста, зачем в п. 17 указывается "БлокироватьДляИзменения = Истина;", но
блокировка же уже устанавливается в п. 12 - п. 15, зачем доп. блокировка ?
И еще вопрос в п. 16 и п. 9 идет очистка данных движений, возможно проще вынести эту очистку 1 раз,
например, перед условием " Если Режим = РежимПроведенияДокумента.Оперативный Тогда" п. 16 ?
Ответить

Ответы

Павел Чистов 10 февраля 2014 г., 18:44


17. Блокируем не то что в документе проводится, а те данные которые могли быть у
документа до перепроведения.
Остальное мелочи...

Анонимный 15 февраля 2014 г., 13:01


А Блокировка.Заблокировать(); не разблокируется после
Движения.СтоимостьТоваров.БлокироватьДляИзменения = Истина;
движения.СтоимостьТоваров.Записать(); ?

Павел Чистов 15 февраля 2014 г., 13:28


Нет.

Анонимный 19 февраля 2014 г., 16:52


А что, если удалять движения только для документов, которые ПЕРЕПРОВОДЯТСЯ.

// Переменная модуля.
Перем мУдалятьДвижения;

Процедура ПередЗаписью(Отказ, РежимЗаписи, РежимПроведения)


мУдалятьДвижения = Не ЭтотОбъект.ЭтоНовый() и Режим =
РежимПроведенияДокумента.Оперативный;
КонецПроцедуры

Процедура ОбработкаПроведения(Отказ, Режим)


.................
//16
Если мУдалятьДвижения Тогда
...........

Павел Чистов 19 февраля 2014 г., 16:57


Можно через доп.свойства передавать признак перепроведения и изменения даты.

Ответить

Анонимный 14 марта 2014 г., 18:00


Допустим перед записью остаток (в регистре ОстаткиТоваров) 2 шт. Списываем 1 шт.
Заблокировали и Записали движения:
//3 Движения.Записать();
В остатке: +1 шт. Блокировки с РН ОстаткиТоваров снялись.

В этот момент другой пользователь другой Расходной безусловно (!) списывает 2 шт (тем же алгоритмом
без проверки остатков) в какой-то момент блокируя регистр:
//7 Движения.ОстаткиТоваров.БлокироватьДляИзменения = Истина;
(метка: 1)
//3 Движения.Записать();
В остатке: -1 шт. Блокировки после этой записи с РН ОстаткиТоваров также снимаются.

(метка: 2)
Наш первый документ дождавшись (дождется ли?) разблокировки, делает запрос к регистру, НЕ
блокируя его (!), и получает отрицательные остатки...
(метка 3)
По первой расходной все откатываем....
Остаток: 0;

(метка: 4)
В какой-то момент второй Документ запрашивает остатки, а так как блокировок регистра на эти запросы
нет, то он может получить и -1 (если код отката проведения первого документа из процедуры
ОбработкаПроведения еще не отработал) и 0 если откат проведения первого документа прошел.
В зависимости от полученного остатка второй документ может быть проведен, а может и нет.

Вопросы;
1. что происходит с фактическими блокировками Таблиц на уровне SQL в Метках 1,2,3, и 4?
2. Блокируются ли Таблицы при откате движений (Отказ = Истина) - метка:3
3. Может быть стоит накладывать дополнительные блокировки ?

С уважением, Михаил Г.
Ответить

Ответы

Павел Чистов 14 марта 2014 г., 21:44


"Блокировки с РН ОстаткиТоваров снялись." - это с какого перепугу они снялись? Блокировка
до конца транзакции установлена.
1. Управляемые блокировки устанавливает сервер 1С:Предприятия, я не SQL.
2. См выше.

Ответить

Анонимный 17 марта 2014 г., 17:51


Почему:
Склад = &Склад
И Номенклатура В
(ВЫБРАТЬ
ДокТЧ.Номенклатура
ИЗ
ДокТЧ КАК ДокТЧ)

а не:
Склад В
(ВЫБРАТЬ
ДокТЧ.Склад
ИЗ
ДокТЧ КАК ДокТЧ)
И Номенклатура В
(ВЫБРАТЬ
ДокТЧ.Номенклатура
ИЗ
ДокТЧ КАК ДокТЧ)
ну и для этого в ВТ ДокТЧ добавить:
РасходнаяТовары.Ссылка.Склад

Есть ли данные о величине разницы в скорости и оптимальности обращения к вирт таблице


"ОстаткиТоваровОстатки" ??

С Ув. Михаил Г.
Ответить

Ответы

Павел Чистов 17 марта 2014 г., 18:07


Какой склад? В статье нет ни слова про склад.

Анонимный 18 марта 2014 г., 00:23


Павел, это в прошлой (первой) статье на эту тему:
http://1c.chistov.pro/2010/06/1-82.html
Пож., поделитесь соображениями по вопросу Запроса =) если есть в разрезе складов
подобная задача - часто встречается.
С Ув. Михаил Г.

Ответить

Бахтияр Ишкабулов 24 марта 2014 г., 02:39


Спасибо за статью, многое прояснил для себя. Такой вопрос: нужно ли ставить блокировку в тех
случаях, когда мы просто пишем какие-то движения и на этом процедура проведения заканчивается?
Т.е.возможно ли, что пока будет выполняться одна транзакция записи у одного пользователя, другой
пользователь считает старые данные? Или же если после Движения.Записать() процедура
заканчивается, то и блокировка не имеет смысла?
Ответить

Ответы

Павел Чистов 24 марта 2014 г., 12:40


Не имеет смысла.

Тарас Курдельчук 14 мая 2014 г., 13:55


На тему этого вопроса, встречный вопрос.
Припустим у меня часто пишется регистр накопления, 100 пользователей и каждую минуту,
как минимум, запись в этот регистр происходит. Если я не буду блокировать регистр в
обработке проведения методом БлокироватьДляИзменения, то при записи регистра на доли
секунды будет блокировать весь "наш регистр", а не его часть, верно? В таком случае, если
использую БлокироватьДляИзменения при проведении, возможно что одновременно будут
сделаны две записи разными пользователями в этот "наш регистр"?

Павел Чистов 14 мая 2014 г., 14:16


Все наоборот. Если не установили БлокироватьДляИзменения - то параллельно можно
провести 2,3, 100 документов, таблицы итогов только слегка распухнут. А если установили, то
обновить итоги сможет только один сеанс в транзакции.
Так же обращаю внимание, что регистр - это не одна таблица, БлокироватьДляИзменения
относится только к итогам.

Ответить

Анонимный 18 апреля 2014 г., 20:48


Эта новая методика никуда не годится, а за правило нужно взять то что нельзя давать пользователю
даже записывать документ если он уходит в минус, поэтому все проверки на отрицательность делаются
при записи до того еще как документ проводится. И если начинается уход в минус то документ даже НЕ
ЗАПИСЫВАЕТСЯ, вот тогда то и можно говорить о какой то новой методике, а так старая методика
намного логичней и правильней
Ответить

Тарас Курдельчук 14 мая 2014 г., 15:12


Также подскажите по поводу уже написаного комментария:
"...Блокировка.Заблокировать(); не разблокируется после
Движения.СтоимостьТоваров.БлокироватьДляИзменения = Истина;
движения.СтоимостьТоваров.Записать(); ?

Павел Чистов15 февраля 2014 г., 13:28


Нет."

Как я понимаю логику, для созданного объекта блокировки командой "разблокировать" будет именно
окончание процедуры ОбработкаПроведения или же явно указать ЗафиксироватьТранзакцию(), методы:
Движения.Записать()
Движения.Регистр.Записать()
Не разблокируют в процедуре все установленные явно объекты
Блокировка = Новый БлокировкаДанных
Верно?
Ответить

Ответы

Павел Чистов 14 мая 2014 г., 15:18


Снятие блокировки происходит только при окончании транзакции в которой она была
установлена.

Ответить

Крутой Инфо 20 мая 2014 г., 21:42


1. В файловом варианте управляемые блокировки будут работать по отдельным измерениям, или все
равно блокируется вся таблица остатков целиком?
2. Можно ли в языке запросов использовать "ДЛЯ ИЗМЕНЕНИЯ", чтобы установить управляемые
блокировки? То бишь, что прочитал, то и заблокировалось?
3. Для чего разрешать в регистре разделение итогов? Или без разделения все равно будет
блокироваться таблица целиком, хоть и выставлен отбор по измерениям?
Ответить

Ответы
Павел Чистов 20 мая 2014 г., 22:01
Все, извините, я больше на подобные вопросы не отвечаю. Вся информация есть в статье и
комментариях.

Павел Чистов 20 мая 2014 г., 22:06


Ну так и быть :)

1. Таблица (не только остатков) блокируется целиком.


2. Можно. Но только в автоматическом режиме блокировок.
3. Для увеличения скорости параллельного изменения таблицы итогов. Погуглите, что такое
разделение итогов.

unf13 4 сентября 2014 г., 16:59


Павел, подскажите, пожалуйста, почему в пункте 8

Запрос.УстановитьПараметр("ТочкаИтоговДляСебестоимости", МоментВремени());

вы указываете просто МоментВремени(), а не как раньше у вас встречалось: ?(Режим =


РежимПроведенияДокумента.Оперативный,Неопределено,МоментВреени())

Ответить

Николай Смирнов 23 июля 2014 г., 11:44


"Если разделение итогов не будет включено и в режиме пользователя, то в большей части случаев
блокировка будет наложена на весь регистр с его таблицами." Нет ли тут ошибки? Насколько я понимаю,
блокировка на таблицу итогов будет наложена только не те измерения, по которым мы производим
запись. Если режим разделения итогов включен, то к таблице итогов будет добавлено новое измерение -
сплиттер, в этом случае писать в таблицу итогов две транзакции смогут даже по одинаковому набору
измерений.
Ответить

Sergey Afanasyev 7 августа 2014 г., 13:21


Добрый день, Павел.
Подскажите, пожалуйста, после перехода на управляемые блокировки, увеличился размер базы в разы
(клиент-сервер). Я так понимаю, что это связано с разрешением разделения итогов. Так ли это? Как-то
можно с этим бороться? Или этого не избежать?
Ответить

Николай Короид 28 августа 2014 г., 09:03


Установил в регистре "Разрешить разделение итогов", так после этого блокировки по разным
измерениям сохранились, и проведение увеличилось до 1-3 минут. До этого максимум до 3 сек
проводился документ. методику использую описанную выше. Использую только регистр остатков.
Зависание происходит при получение остатков после записи в регистр.
Ответить
Анонимный 23 сентября 2014 г., 10:09
> Когда произойдет блокировка записей? В момент записи данных.
Вот этот момент хотелось бы и прояснить.

1 Случай:

Движения.ОстаткиТоваров.Очистить();

Для каждого Стр Из СписокТоваров Цикл


Движение = Движения.ОстаткиТоваров.ДобавитьРасход();
Движение.Период = Дата;
Движение.Товар = Стр.Товар;
Движение.Количество = Стр.Количество;
КонецЦикла;

//7
Движения.ОстаткиТоваров.БлокироватьДляИзменения = Истина;

//3
Движения.Записать();

Здесь будут какие записи заблокированы?

2 Случай (если оперативное перепроведение)

//16
Если Режим = РежимПроведенияДокумента.Оперативный Тогда
Движения.СтоимостьТоваров.Очистить();
//17
Движения.СтоимостьТоваров.БлокироватьДляИзменения = Истина;
Движения.СтоимостьТоваров.Записать();
КонецЕсли;

Таким образом в первом случае мы получаем блокировку по тем записям, которые будут сделаны.
А во втором случае по тем записям, которые могут существовать. Почему?

Если опираться на логику первого случая, то во втором должен блокироваться пустой набор. Или как?
Ответить

Ответы

Павел Чистов 23 сентября 2014 г., 11:16


1. Будут заблокированы вновь созданные записи и записи которые могли существовать у
документа до его перепроведения.
2. Будут заблокированы записи которые могли существовать у документа до его
перепроведения.

Анонимный 23 сентября 2014 г., 12:02


Спасибо за оперативный ответ!
С уважением, Алексей.

Анонимный 24 сентября 2014 г., 09:10


"2. Будут заблокированы записи которые могли существовать у документа до его
перепроведения."-Так мы вроде очистили записи,разве нет?
Анонимный 25 сентября 2014 г., 00:10
Мы очистили их только в оперативной памяти, запрос же будет читать их из базы. Поэтому,
чтобы они не попадали опять в выборку необходимо очищенные в памяти наборы записать в
базу перед чтением запросом.

У меня другой вопрос. Не лучше ли в п.17 вместо Движения.СтоимостьТоваров.Записаоть()


использовать, как в п.3 Движения.Записать() ?

Павел Чистов 25 сентября 2014 г., 02:13


"Не лучше ли в п.17 вместо Движения.СтоимостьТоваров.Записаоть() использовать, как в п.3
Движения.Записать() ?"

Нет. Точнее без разницы. Нам нужно принудительно записать движения именно по одному
регистру.

Анонимный 25 сентября 2014 г., 09:58


Anonymous что бы не попадали в выборку достаточно использовать Граница(не включая)

Анонимный 25 сентября 2014 г., 10:01


японял что они будут очищены и записаны в базу,зачем их блокировать если там ничего нет?

Павел Чистов 25 сентября 2014 г., 10:08


"что бы не попадали в выборку достаточно использовать Граница(не включая)" - а если
пользователь дату документа поменял?

"японял что они будут очищены и записаны в базу,зачем их блокировать если там ничего нет?"
- у Вас транзакция меняет записи в базе, в самой базе, до завершения транзакции, все есть.

Анонимный 26 сентября 2014 г., 12:46


т.е. метод записать() в базу ничего не пишет сразу а только по окончании транзакции модуля
проведения?так получается?а как тогда мы очищаем движения и записываем и тут же запрос
делаем,что бы прочитать остатки без движений?Противоречите сами себе.

Павел Чистов 26 сентября 2014 г., 12:49


"т.е. метод записать() в базу ничего не пишет сразу а только по окончании транзакции модуля
проведения?так получается?а как тогда мы очищаем движения и записываем и тут же запрос
делаем,что бы прочитать остатки без движений?Противоречите сами себе."

Вы видимо не понимаете, что такое транзакция, кэш транзакции...

Анонимный 26 сентября 2014 г., 13:30


Так я бы и не читал тогда статью,но в ней не сказано,что этот метод меняет только кэш
транзакции и т.д.я ведь не знаю как 1с методы реализовала,вот и хотелось узнать,но вместо
чего то понятного получается все очень запутанно у разработчиков платформы 1с,все эти
методы записывать или не записывать,при проведении нет параметра старой даты(если дату
поменяли),приходится костыли использовать что-бы проверить остатки при списании,так как
не понятно где искать старые записи для того что бы не учесть их.Как вы сказали что при
включенном механизме автоудаления регистры вначале записываются пустые автоматом в
базу а в кэше остаются старые значения,зачем еще раз очищать и записывать.

Ответить

Анонимный 23 сентября 2014 г., 14:38


вопрос по этому коду :Движения.ОстаткиТоваров.Очистить();

Для каждого Стр Из СписокТоваров Цикл


Движение = Движения.ОстаткиТоваров.ДобавитьРасход();
Движение.Период = Дата;
Движение.Товар = Стр.Товар;
Движение.Количество = Стр.Количество;
КонецЦикла;

//7
Движения.ОстаткиТоваров.БлокироватьДляИзменения = Истина;

//3
Движения.Записать();
------------>>Здесь вы блокируете Движения.Остатки это фактически набор записей с отбором по
регистратору,какой в этом смысл если записи с другими регистраторами не заблокированы.Может
правильнее через запрос для изменения всей таблицы,либо как ниже вы делаете через объект
блокировка?А так же в статье не рассмотрен вопрос про блокировки через запрос.
Ответить

Анонимный 25 сентября 2014 г., 14:27


Непонятен смысл самого условия оперативного проведения документа в п.16. Ведь система вылетает с
ошибкой несвязанной с режимом проведения документа. Там ошибка либо "Операции сравнения на
больше-меньше допустимы только для значений совпадающих примитивных типов", это если мы не
обрабатываем возможность на NULL в запросе, либо попытка деления на нуль, если мы в запросе
ставим условие на ЕСТЬNULL, но не обрабатываем деление на 0 при расчете себестоимости в цикле.
При неоперативном проведении такое тоже может случиться, например, если мы перепроводим
документ два раза неоперативно задним числом, но разными датами, где вторая дата больше первой,
результат будет такой же. На мой скромный взгляд, условие вообще не нужно. А так как мы все равно
делаем записи всех регистров в п.3, т.е со всеми правильными блокировками, может быть вместо этого
условия стоит добавить в пп.1и2 соответственно еще и
Движения.СтоимостьТоваров.Записывать=Истина; и Движения.СтоимостьТоваров.Очистить();?
Ответить

Анонимный 26 сентября 2014 г., 15:45


Хотелось бы у вас спросить по поводу новой фишки "мини сервер" для чего она понадобилась,так как
проверяя у себя блокировки,обнаружил что при проведении блокируется вся таблица документов,т.е.
при проведении другой документ даже не открыть,не связано ли это с новой платформой,кстати первый
раз нормально отработала,потом вот так начала работать.
Ответить

Анонимный 29 сентября 2014 г., 18:21


Ну все равно спасибо огромное за статью,не представляю как бы разбирался без нее с
проведениями.Еще бы по бу зп и бизнес процессам посмотреть бы тонкости.
Ответить

Анонимный 30 сентября 2014 г., 01:04


не порекомендуете книгу почитать более развернуто про блокировки и их виды,на что они действуют ,на
кэш или на таблицы не понятно.
Ответить

Анонимный 15 ноября 2014 г., 13:52


Я всё же не могу понять, зачем нам вторая таблица. Ведь это избыточные данные. Ведь можно по одной
таблице партий определять остатки.
Ответить

Анонимный 16 ноября 2014 г., 15:39


такой вопрос,вы говорите что в автоматических блокировках можно через запрос накладывать
блокировку,почему у вас через объект блокировка сделано?
Ответить

Анонимный 16 ноября 2014 г., 16:52


у вас описка,в конце нужно делить сумму на количество
Ответить

Ответы

Павел Чистов 16 ноября 2014 г., 17:03


Нет мам описки. Все правильно.

Ответить

Анонимный 16 ноября 2014 г., 18:03


а нет все правильно это я сам спутал цену и сумму
Ответить

Анонимный 19 ноября 2014 г., 13:41


не пойму - "Движение.Стоимость = Списать / ВыборкаПартия.КоличествоОстаток *
ВыборкаПартия.СтоимостьОстаток;".
а какже проблема копеек?
Ответить

Ответы

Павел Чистов 19 ноября 2014 г., 16:45


Сформулируйте "проблему копеек", потом посмотрите на формулу.

Анонимный 20 ноября 2014 г., 08:16


я извиняюсь конечно, но вот здесь (http://infostart.ru/public/102366/) говорится:

7. Правильный порядок расположения операндов при расчете себестоимости. Проблема


копеек. Есть мнение, что правильно делать так:

НоваяЗапись.Сумма = Выборка.КоличествоДокумент * Выборка.СуммаОстаток /


Выборка.КоличествоОстаток;
То есть, умножение идет перед делением, что обеспечит в случае 3 * 10 / 3 число 10 а не
число 9.99999999(9), как может быть при совсем неправильном порядке, однако методически
такой способ не считается верным (это слова преподавателя из 1С), во-первых, деление по
методике должно идти сначала, но деление не суммы на остаток количества, а количества к
списанию на количество остатка, во-вторых, при равенстве количеств, лучше просто взять
сумму, поэтому делая так, как ниже, проблем быть не должно:

НоваяЗапись.Сумма = ?(Выборка.КоличествоДокумент = Выборка.КоличествоОстаток,


Выборка.СуммаОстаток,
Окр(Выборка.КоличествоДокумент / Выборка.КоличествоОстаток,2) *
Выборка.СуммаОстаток);

но реально сейчас посмотрел Вашу формулу и не нашёл этой проблемы у Вас.

т.е. - Ваш вариант всёже верный?

Ответить

Нравится 12

Загрузить еще

Оценить